pkgs/games/darkplaces/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , zlib
   5 , libjpeg
   6 , SDL2
   7 , libvorbis
   8 }:
   9 stdenv.mkDerivation rec {
  10   pname = "darkplaces";
  11   version = "unstable-2022-05-10";
  12
  13   src = fetchFromGitHub {
  14     owner = "DarkPlacesEngine";
  15     repo = "darkplaces";
  16     rev = "f16954a9d40168253ac5d9890dabcf7dbd266cd9";
  17     hash = "sha256-5KsUcgHbuzFUE6LcclqI8VPSFbXZzBnxzOBB9Kf8krI=";
  18   };
  19
  20   buildInputs = [
  21     zlib
  22     libjpeg
  23     SDL2
  24   ];
  25
  26   buildFlags = [ "release" ];
  27
  28   installPhase = ''
  29     runHook preInstall
  30
  31     mkdir -p $out/bin
  32     install -m755 darkplaces-sdl $out/bin/darkplaces
  33     install -m755 darkplaces-dedicated $out/bin/darkplaces-dedicated
  34
  35     runHook postInstall
  36   '';
  37
  38   postFixup = ''
  39     patchelf \
  40       --add-needed ${libvorbis}/lib/libvorbisfile.so \
  41       --add-needed ${libvorbis}/lib/libvorbis.so \
  42       $out/bin/darkplaces
  43   '';
  44
  45   meta = with lib; {
  46     homepage = "https://www.icculus.org/twilight/darkplaces/";
  47     description = "Quake 1 engine implementation by LadyHavoc";
  48     longDescription = ''
  49       A game engine based on the Quake 1 engine by id Software.
  50       It improves and builds upon the original 1996 engine by adding modern
  51       rendering features, and expanding upon the engine's native game code
  52       language QuakeC, as well as supporting additional map and model formats.
  53     '';
  54     maintainers = with maintainers; [ necrophcodr ];
  55     license = licenses.gpl2Plus;
  56     platforms = platforms.linux;
  57   };
  58 }