pkgs/misc/ghostscript/default.nix

   1 { config
   2 , stdenv
   3 , lib
   4 , fetchurl
   5 , pkg-config
   6 , zlib
   7 , expat
   8 , openssl
   9 , autoconf
  10 , libjpeg
  11 , libpng
  12 , libtiff
  13 , freetype
  14 , fontconfig
  15 , libpaper
  16 , jbig2dec
  17 , libiconv
  18 , ijs
  19 , lcms2
  20 , callPackage
  21 , bash
  22 , buildPackages
  23 , openjpeg
  24 , fixDarwinDylibNames
  25 , cupsSupport ? config.ghostscript.cups or (!stdenv.hostPlatform.isDarwin)
  26 , cups
  27 , x11Support ? cupsSupport
  28 , xorg # with CUPS, X11 only adds very little
  29 , dynamicDrivers ? true
  30
  31 # for passthru.tests
  32 , graphicsmagick
  33 , imagemagick
  34 , libspectre
  35 , lilypond
  36 , pstoedit
  37 , python3
  38 }:
  39
  40 let
  41   fonts = stdenv.mkDerivation {
  42     name = "ghostscript-fonts";
  43
  44     srcs = [
  45       (fetchurl {
  46         url = "mirror://sourceforge/gs-fonts/ghostscript-fonts-std-8.11.tar.gz";
  47         hash = "sha256-DrbzVhGfLkmyVjIQhS4X9X+dzFdV81Cmmkag1kGgxAE=";
  48       })
  49       (fetchurl {
  50         url = "mirror://gnu/ghostscript/gnu-gs-fonts-other-6.0.tar.gz";
  51         hash = "sha256-gUbMzEaZ/p2rhBRGvdFwOfR2nJA+zrVECRiLkgdUqrM=";
  52       })
  53       # ... add other fonts here
  54     ];
  55
  56     installPhase = ''
  57       mkdir "$out"
  58       mv -v * "$out/"
  59     '';
  60   };
  61
  62 in
  63 stdenv.mkDerivation rec {
  64   pname = "ghostscript${lib.optionalString x11Support "-with-X"}";
  65   version = "10.04.0";
  66
  67   src = fetchurl {
  68     url = "https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs${lib.replaceStrings ["."] [""] version}/ghostscript-${version}.tar.xz";
  69     hash = "sha256-Un7vC2zQTs8cjXoReWxppS00/+Nq/KhqQAcpovwByIc=";
  70   };
  71
  72   patches = [
  73     ./urw-font-files.patch
  74     ./doc-no-ref.diff
  75   ];
  76
  77   outputs = [ "out" "man" "doc" "fonts" ];
  78
  79   enableParallelBuilding = true;
  80
  81   depsBuildBuild = [
  82     buildPackages.stdenv.cc
  83   ];
  84
  85   nativeBuildInputs = [ pkg-config autoconf zlib ]
  86     ++ lib.optional cupsSupport cups
  87     ++ lib.optional stdenv.hostPlatform.isDarwin fixDarwinDylibNames;
  88
  89   buildInputs = [
  90     zlib expat openssl
  91     libjpeg libpng libtiff freetype fontconfig libpaper jbig2dec
  92     libiconv ijs lcms2 bash openjpeg
  93   ]
  94   ++ lib.optionals x11Support [ xorg.libICE xorg.libX11 xorg.libXext xorg.libXt ]
  95   ++ lib.optional cupsSupport cups
  96   ;
  97
  98   preConfigure = ''
  99     # https://ghostscript.com/doc/current/Make.htm
 100     export CCAUX=$CC_FOR_BUILD
 101     ${lib.optionalString cupsSupport ''export CUPSCONFIG="${cups.dev}/bin/cups-config"''}
 102
 103     rm -rf jpeg libpng zlib jasper expat tiff lcms2mt jbig2dec freetype cups/libs ijs openjpeg
 104
 105     sed "s@if ( test -f \$(INCLUDE)[^ ]* )@if ( true )@; s@INCLUDE=/usr/include@INCLUDE=/no-such-path@" -i base/unix-aux.mak
 106     sed "s@^ZLIBDIR=.*@ZLIBDIR=${zlib.dev}/include@" -i configure.ac
 107
 108     autoconf
 109   '';
 110
 111   configureFlags = [
 112     "--with-system-libtiff"
 113     "--without-tesseract"
 114   ] ++ lib.optionals dynamicDrivers [
 115     "--enable-dynamic"
 116     "--disable-hidden-visibility"
 117   ] ++ lib.optionals x11Support [
 118     "--with-x"
 119   ] ++ lib.optionals cupsSupport [
 120     "--enable-cups"
 121   ];
 122
 123   # make check does nothing useful
 124   doCheck = false;
 125
 126   # don't build/install statically linked bin/gs
 127   buildFlags = [ "so" ]
 128     # without -headerpad, the following error occurs on Darwin when compiling with X11 support (as of 10.02.0)
 129     # error: install_name_tool: changing install names or rpaths can't be redone for: [...]libgs.dylib.10 (the program must be relinked, and you may need to use -headerpad or -headerpad_max_install_names)
 130     ++ lib.optional (x11Support && stdenv.hostPlatform.isDarwin) "LDFLAGS=-headerpad_max_install_names";
 131   installTargets = [ "soinstall" ];
 132
 133   postInstall = ''
 134     ln -s gsc "$out"/bin/gs
 135
 136     cp -r Resource "$out/share/ghostscript/${version}"
 137
 138     mkdir -p $fonts/share/fonts
 139     cp -rv ${fonts}/* "$fonts/share/fonts/"
 140     ln -s "$fonts/share/fonts" "$out/share/ghostscript/fonts"
 141   '';
 142
 143   # dynamic library name only contains major version number, eg. '10'
 144   dylib_version = lib.versions.major version;
 145   preFixup = lib.optionalString stdenv.hostPlatform.isDarwin ''
 146     for file in $out/bin/{gs,gsc,gsx}; do
 147       install_name_tool -change libgs.$dylib_version.dylib $out/lib/libgs.$dylib_version.dylib $file
 148     done
 149   '';
 150
 151   # validate dynamic linkage
 152   doInstallCheck = true;
 153   installCheckPhase = ''
 154     runHook preInstallCheck
 155
 156     $out/bin/gs --version
 157     $out/bin/gsx --version
 158     pushd examples
 159     for f in *.{ps,eps,pdf}; do
 160       echo "Rendering $f"
 161       $out/bin/gs \
 162         -dNOPAUSE \
 163         -dBATCH \
 164         -sDEVICE=bitcmyk \
 165         -sOutputFile=/dev/null \
 166         -r600 \
 167         -dBufferSpace=100000 \
 168         $f
 169     done
 170     popd # examples
 171
 172     runHook postInstallCheck
 173   '';
 174
 175   passthru.tests = {
 176     test-corpus-render = callPackage ./test-corpus-render.nix {};
 177     inherit graphicsmagick imagemagick libspectre lilypond pstoedit;
 178     inherit (python3.pkgs) matplotlib;
 179   };
 180
 181   meta = {
 182     homepage = "https://www.ghostscript.com/";
 183     description = "PostScript interpreter (mainline version)";
 184     longDescription = ''
 185       Ghostscript is the name of a set of tools that provides (i) an
 186       interpreter for the PostScript language and the PDF file format,
 187       (ii) a set of C procedures (the Ghostscript library) that
 188       implement the graphics capabilities that appear as primitive
 189       operations in the PostScript language, and (iii) a wide variety
 190       of output drivers for various file formats and printers.
 191     '';
 192     license = lib.licenses.agpl3Plus;
 193     platforms = lib.platforms.all;
 194     maintainers = [ lib.maintainers.tobim ];
 195     mainProgram = "gs";
 196   };
 197 }