pkgs/applications/audio/aucatctl/default.nix

   1 { lib, stdenv, fetchurl, sndio, libbsd }:
   2
   3 stdenv.mkDerivation (finalAttrs: {
   4   pname = "aucatctl";
   5   version = "0.1";
   6
   7   src = fetchurl {
   8     url = "http://www.sndio.org/${finalAttrs.pname}-${finalAttrs.version}.tar.gz";
   9     sha256 = "524f2fae47db785234f166551520d9605b9a27551ca438bd807e3509ce246cf0";
  10   };
  11
  12   buildInputs = [ sndio ]
  13     ++ lib.optional (!stdenv.isDarwin && !stdenv.hostPlatform.isBSD)
  14     libbsd;
  15
  16   outputs = [ "out" "man" ];
  17
  18   preBuild = ''
  19     makeFlagsArray+=("PREFIX=$out")
  20   '' + lib.optionalString
  21     (!stdenv.isDarwin && !stdenv.hostPlatform.isBSD) ''
  22       makeFlagsArray+=(LDADD="-lsndio -lbsd")
  23
  24       # Fix warning about implicit declaration of function 'strlcpy'
  25       substituteInPlace aucatctl.c \
  26         --replace '#include <string.h>' '#include <bsd/string.h>'
  27     '';
  28
  29   meta = with lib; {
  30     description = "The aucatctl utility sends MIDI messages to control sndiod and/or aucat volumes";
  31     homepage = "http://www.sndio.org";
  32     license = licenses.isc;
  33     maintainers = with maintainers; [ sna ];
  34     platforms = platforms.unix;
  35     mainProgram = "aucatctl";
  36   };
  37 })