pkgs/applications/audio/mpc123/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitLab
   4 , gettext
   5 , libao
   6 , libmpcdec
   7 }:
   8
   9 stdenv.mkDerivation (finalAttrs: {
  10   pname = "mpc123";
  11   version = "0.2.4";
  12
  13   src = fetchFromGitLab {
  14     domain = "salsa.debian.org";
  15     owner = "debian";
  16     repo = "mpc123";
  17     rev = "upstream/${finalAttrs.version}";
  18     hash = "sha256-+/yxb19CJzyjQmT3O21pEmPR5YudmyCxWwo+W3uOB9Q=";
  19   };
  20
  21   strictDeps = true;
  22
  23   nativeBuildInputs = [
  24     gettext
  25   ];
  26
  27   buildInputs = [
  28     gettext
  29     libao
  30     libmpcdec
  31   ];
  32
  33   makeFlags = [
  34     "CC=${stdenv.cc.targetPrefix}cc"
  35   ];
  36
  37   # Workaround build failure on -fno-common toolchains like upstream
  38   # gcc-10. Otherwise build fails as:
  39   #   ld: /build/cc566Cj9.o:(.bss+0x0): multiple definition of `mpc123_file_reader'; ao.o:(.bss+0x40): first defined here
  40   env.NIX_CFLAGS_COMPILE = "-fcommon";
  41
  42   # XXX: Should install locales too (though there's only 1 available).
  43   installPhase = ''
  44     runHook preInstall
  45
  46     mkdir -p "$out/bin"
  47     cp -v mpc123 "$out/bin"
  48
  49     runHook postInstall
  50   '';
  51
  52   meta = {
  53     description = "A Musepack (.mpc) audio player";
  54     homepage = "https://github.com/bucciarati/mpc123";
  55     license = lib.licenses.gpl2Plus;
  56     mainProgram = "mpc123";
  57     maintainers = [ ];
  58     platforms = lib.platforms.unix;
  59   };
  60 })