pkgs/applications/audio/uade/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitLab
   4 , python3
   5 , pkg-config
   6 , which
   7 , makeWrapper
   8 , libao
   9 , bencodetools
  10 , sox
  11 , lame
  12 , flac
  13 , vorbis-tools
  14 # https://gitlab.com/uade-music-player/uade/-/issues/38
  15 , withWriteAudio ? !stdenv.hostPlatform.isDarwin
  16 }:
  17
  18 stdenv.mkDerivation rec {
  19   pname = "uade";
  20   version = "3.02";
  21
  22   src = fetchFromGitLab {
  23     owner = "uade-music-player";
  24     repo = "uade";
  25     rev = "uade-${version}";
  26     sha256 = "sha256-skPEXBQwyr326zCmZ2jwGxcBoTt3Y/h2hagDeeqbMpw=";
  27   };
  28
  29   postPatch = ''
  30     patchShebangs configure
  31     substituteInPlace configure \
  32       --replace 'PYTHON_SETUP_ARGS=""' 'PYTHON_SETUP_ARGS="--prefix=$out"'
  33     substituteInPlace src/frontends/mod2ogg/mod2ogg2.sh.in \
  34       --replace '-e stat' '-n stat' \
  35       --replace '/usr/local' "$out"
  36     substituteInPlace python/uade/generate_oscilloscope_view.py \
  37       --replace "default='uade123'" "default='$out/bin/uade123'"
  38     # https://gitlab.com/uade-music-player/uade/-/issues/37
  39     substituteInPlace write_audio/Makefile.in \
  40       --replace 'g++' '${stdenv.cc.targetPrefix}c++'
  41   '';
  42
  43   nativeBuildInputs = [
  44     pkg-config
  45     which
  46     makeWrapper
  47   ] ++ lib.optionals withWriteAudio [
  48     python3
  49   ];
  50
  51   buildInputs = [
  52     libao
  53     bencodetools
  54     sox
  55     lame
  56     flac
  57     vorbis-tools
  58   ] ++ lib.optionals withWriteAudio [
  59     (python3.withPackages (p: with p; [
  60       pillow
  61       tqdm
  62       more-itertools
  63     ]))
  64   ];
  65
  66   configureFlags = [
  67     "--bencode-tools-prefix=${bencodetools}"
  68     "--with-text-scope"
  69   ] ++ lib.optionals (!withWriteAudio) [
  70     "--without-write-audio"
  71   ];
  72
  73   enableParallelBuilding = true;
  74
  75   hardeningDisable = [ "format" ];
  76
  77   postInstall = ''
  78     wrapProgram $out/bin/mod2ogg2.sh \
  79       --prefix PATH : $out/bin:${lib.makeBinPath [ sox lame flac vorbis-tools ]}
  80     # This is an old script, don't break expectations by renaming it
  81     ln -s $out/bin/mod2ogg2{.sh,}
  82   '' + lib.optionalString withWriteAudio ''
  83     wrapProgram $out/bin/generate_amiga_oscilloscope_view \
  84       --prefix PYTHONPATH : "$PYTHONPATH:$out/${python3.sitePackages}"
  85   '';
  86
  87   meta = with lib; {
  88     description = "Plays old Amiga tunes through UAE emulation and cloned m68k-assembler Eagleplayer API";
  89     homepage = "https://zakalwe.fi/uade/";
  90     # It's a mix of licenses. "GPL", Public Domain, "LGPL", GPL2+, BSD, LGPL21+ and source code with unknown licenses. E.g.
  91     # - hippel-coso player is "[not] under any Open Source certified license"
  92     # - infogrames player is disassembled from Andi Silvas player, unknown license
  93     # Let's make it easy and flag the whole package as unfree.
  94     license = licenses.unfree;
  95     maintainers = with maintainers; [ OPNA2608 ];
  96     mainProgram = "uade123";
  97     platforms = platforms.unix;
  98   };
  99 }