pkgs/applications/blockchains/go-ethereum/default.nix

   1 { lib, stdenv, buildGoModule, fetchFromGitHub, libobjc, IOKit, nixosTests }:
   2
   3 let
   4   # A list of binaries to put into separate outputs
   5   bins = [
   6     "geth"
   7     "clef"
   8   ];
   9
  10 in buildGoModule rec {
  11   pname = "go-ethereum";
  12   version = "1.13.5";
  13
  14   src = fetchFromGitHub {
  15     owner = "ethereum";
  16     repo = pname;
  17     rev = "v${version}";
  18     sha256 = "sha256-UbRsY9fSUYAwPcLfGGDHeqvSsLKUKR+2a93jH5xA9uQ=";
  19   };
  20
  21   vendorHash = "sha256-dOvpOCMxxmcAaticSLVlro1L4crAVJWyvgx/JZZ7buE=";
  22
  23   doCheck = false;
  24
  25   outputs = [ "out" ] ++ bins;
  26
  27   # Move binaries to separate outputs and symlink them back to $out
  28   postInstall = lib.concatStringsSep "\n" (
  29     builtins.map (bin: "mkdir -p \$${bin}/bin && mv $out/bin/${bin} \$${bin}/bin/ && ln -s \$${bin}/bin/${bin} $out/bin/") bins
  30   );
  31
  32   subPackages = [
  33     "cmd/abidump"
  34     "cmd/abigen"
  35     "cmd/bootnode"
  36     "cmd/clef"
  37     "cmd/devp2p"
  38     "cmd/ethkey"
  39     "cmd/evm"
  40     "cmd/faucet"
  41     "cmd/geth"
  42     "cmd/p2psim"
  43     "cmd/rlpdump"
  44     "cmd/utils"
  45   ];
  46
  47   # Following upstream: https://github.com/ethereum/go-ethereum/blob/v1.11.6/build/ci.go#L218
  48   tags = [ "urfave_cli_no_docs" ];
  49
  50   # Fix for usb-related segmentation faults on darwin
  51   propagatedBuildInputs =
  52     lib.optionals stdenv.isDarwin [ libobjc IOKit ];
  53
  54   passthru.tests = { inherit (nixosTests) geth; };
  55
  56   meta = with lib; {
  57     homepage = "https://geth.ethereum.org/";
  58     description = "Official golang implementation of the Ethereum protocol";
  59     license = with licenses; [ lgpl3Plus gpl3Plus ];
  60     maintainers = with maintainers; [ RaghavSood ];
  61   };
  62 }