pkgs/applications/blockchains/lnd/default.nix

   1 { buildGoModule
   2 , fetchFromGitHub
   3 , lib
   4 , tags ? [ "autopilotrpc" "signrpc" "walletrpc" "chainrpc" "invoicesrpc" "watchtowerrpc" "routerrpc" "monitoring" "kvdb_postgres" "kvdb_etcd" ]
   5 }:
   6
   7 buildGoModule rec {
   8   pname = "lnd";
   9   version = "0.17.4-beta";
  10
  11   src = fetchFromGitHub {
  12     owner = "lightningnetwork";
  13     repo = "lnd";
  14     rev = "v${version}";
  15     hash = "sha256-O6cGK4UMKrZpYqtghjjqqLBStLG5GEi/Q5liR557I8s=";
  16   };
  17
  18   vendorHash = "sha256-eaQmM5bfsUmzTiUALX543VBQRJK+TqW2i28npwSrn3Q=";
  19
  20   subPackages = [ "cmd/lncli" "cmd/lnd" ];
  21
  22   preBuild = let
  23     buildVars = {
  24       RawTags = lib.concatStringsSep "," tags;
  25       GoVersion = "$(go version | egrep -o 'go[0-9]+[.][^ ]*')";
  26     };
  27     buildVarsFlags = lib.concatStringsSep " " (lib.mapAttrsToList (k: v: "-X github.com/lightningnetwork/lnd/build.${k}=${v}") buildVars);
  28   in
  29   lib.optionalString (tags != []) ''
  30     buildFlagsArray+=("-tags=${lib.concatStringsSep " " tags}")
  31     buildFlagsArray+=("-ldflags=${buildVarsFlags}")
  32   '';
  33
  34   meta = with lib; {
  35     description = "Lightning Network Daemon";
  36     homepage = "https://github.com/lightningnetwork/lnd";
  37     license = licenses.mit;
  38     maintainers = with maintainers; [ cypherpunk2140 prusnak ];
  39   };
  40 }