pkgs/applications/blockchains/monero-cli/default.nix

   1 { lib, stdenv, fetchFromGitHub, cmake, pkg-config
   2 , boost, miniupnpc, openssl, unbound
   3 , zeromq, pcsclite, readline, libsodium, hidapi
   4 , randomx, rapidjson
   5 , CoreData, IOKit, PCSC
   6 , trezorSupport ? true, libusb1, protobuf, python3
   7 }:
   8
   9 let
  10   # submodules
  11   supercop = fetchFromGitHub {
  12     owner = "monero-project";
  13     repo = "supercop";
  14     rev = "633500ad8c8759995049ccd022107d1fa8a1bbc9";
  15     hash = "sha256-26UmESotSWnQ21VbAYEappLpkEMyl0jiuCaezRYd/sE=";
  16   };
  17   trezor-common = fetchFromGitHub {
  18     owner = "trezor";
  19     repo = "trezor-common";
  20     rev = "bc28c316d05bf1e9ebfe3d7df1ab25831d98d168";
  21     hash = "sha256-F1Hf1WwHqXMd/5OWrdkpomszACTozDuC7DQXW3p6248=";
  22   };
  23
  24 in
  25
  26 stdenv.mkDerivation rec {
  27   pname = "monero-cli";
  28   version = "0.18.3.3";
  29
  30   src = fetchFromGitHub {
  31     owner = "monero-project";
  32     repo = "monero";
  33     rev = "v${version}";
  34     hash = "sha256-1LkKIrud317BEE+713t5wiJV6FcDlJdj4ypXPR0bKTs=";
  35   };
  36
  37   patches = [
  38     ./use-system-libraries.patch
  39   ];
  40
  41   postPatch = ''
  42     # manually install submodules
  43     rmdir external/{supercop,trezor-common}
  44     ln -sf ${supercop} external/supercop
  45     ln -sf ${trezor-common} external/trezor-common
  46     # export patched source for monero-gui
  47     cp -r . $source
  48   '';
  49
  50   nativeBuildInputs = [ cmake pkg-config ];
  51
  52   buildInputs = [
  53     boost miniupnpc openssl unbound
  54     zeromq pcsclite readline
  55     libsodium hidapi randomx rapidjson
  56     protobuf
  57   ] ++ lib.optionals stdenv.isDarwin [ IOKit CoreData PCSC ]
  58     ++ lib.optionals trezorSupport [ libusb1 protobuf python3 ];
  59
  60   cmakeFlags = [
  61     "-DUSE_DEVICE_TREZOR=ON"
  62     "-DBUILD_GUI_DEPS=ON"
  63     "-DReadline_ROOT_DIR=${readline.dev}"
  64     "-DRandomX_ROOT_DIR=${randomx}"
  65   ] ++ lib.optional stdenv.isDarwin "-DBoost_USE_MULTITHREADED=OFF";
  66
  67   outputs = [ "out" "source" ];
  68
  69   meta = with lib; {
  70     description = "Private, secure, untraceable currency";
  71     homepage    = "https://getmonero.org/";
  72     license     = licenses.bsd3;
  73     platforms   = platforms.all;
  74     maintainers = with maintainers; [ rnhmjoj ];
  75     mainProgram = "monero-wallet-cli";
  76   };
  77 }