pkgs/applications/editors/emacs/default.nix

   1 { lib, pkgs }:
   2
   3 lib.makeScope pkgs.newScope (self:
   4   let
   5     gconf = pkgs.gnome2.GConf;
   6     inherit (self) callPackage;
   7     stdenv = if pkgs.stdenv.isDarwin
   8              then pkgs.darwin.apple_sdk_11_0.stdenv
   9              else pkgs.stdenv;
  10     inheritedArgs = {
  11       inherit gconf;
  12       inherit stdenv;
  13
  14       inherit (pkgs.darwin) sigtool;
  15       inherit (pkgs.darwin.apple_sdk_11_0) llvmPackages_14;
  16       inherit (pkgs.darwin.apple_sdk_11_0.frameworks)
  17         Accelerate AppKit Carbon Cocoa GSS ImageCaptureCore ImageIO IOKit OSAKit
  18         Quartz QuartzCore UniformTypeIdentifiers WebKit;
  19       gnutls =
  20         if pkgs.stdenv.isDarwin
  21         then pkgs.gnutls.override {
  22           inherit stdenv;
  23           inherit (pkgs.darwin.apple_sdk_11_0.frameworks) Security;
  24         }
  25         else pkgs.gnutls;
  26     };
  27   in {
  28     sources = import ./sources.nix {
  29       inherit lib;
  30       inherit (pkgs)
  31         fetchFromBitbucket
  32         fetchFromSavannah;
  33     };
  34
  35     emacs28 = callPackage (self.sources.emacs28) inheritedArgs;
  36
  37     emacs28-gtk2 = self.emacs28.override {
  38       withGTK2 = true;
  39     };
  40
  41     emacs28-gtk3 = self.emacs28.override {
  42       withGTK3 = true;
  43     };
  44
  45     emacs28-nox = pkgs.lowPrio (self.emacs28.override {
  46       noGui = true;
  47     });
  48
  49     emacs29 = callPackage (self.sources.emacs29) inheritedArgs;
  50
  51     emacs29-gtk3 = self.emacs29.override {
  52       withGTK3 = true;
  53     };
  54
  55     emacs29-nox = self.emacs29.override {
  56       noGui = true;
  57     };
  58
  59     emacs29-pgtk = self.emacs29.override {
  60       withPgtk = true;
  61     };
  62
  63     emacs28-macport = callPackage (self.sources.emacs28-macport) inheritedArgs;
  64
  65     emacs29-macport = callPackage (self.sources.emacs29-macport) inheritedArgs;
  66   })