pkgs/applications/editors/kakoune/wrapper.nix

   1 { symlinkJoin, makeWrapper, kakoune, plugins ? [], configure ? {} }:
   2
   3 let
   4   # "plugins" is the preferred way, but some configurations may be
   5   # using "configure.plugins", so accept both
   6   requestedPlugins = plugins ++ (configure.plugins or []);
   7
   8 in
   9   symlinkJoin {
  10     name = "kakoune-${kakoune.version}";
  11
  12     nativeBuildInputs = [ makeWrapper ];
  13
  14     paths = [ kakoune ] ++ requestedPlugins;
  15
  16     postBuild = ''
  17       # location of kak binary is used to find ../share/kak/autoload,
  18       # unless explicitly overriden with KAKOUNE_RUNTIME
  19       rm "$out/bin/kak"
  20       makeWrapper "${kakoune}/bin/kak" "$out/bin/kak" --set KAKOUNE_RUNTIME "$out/share/kak"
  21
  22       # currently kakoune ignores doc files if they are symlinks, so workaround by
  23       # copying doc files over, so they become regular files...
  24       mkdir "$out/DELETE_ME"
  25       mv "$out/share/kak/doc" "$out/DELETE_ME"
  26       cp -r --dereference "$out/DELETE_ME/doc" "$out/share/kak"
  27       rm -Rf "$out/DELETE_ME"
  28     '';
  29
  30     meta = kakoune.meta // { priority = (kakoune.meta.priority or 0) - 1; };
  31   }