pkgs/applications/editors/notepad-next/default.nix

   1 { mkDerivation, lib, fetchFromGitHub, qmake, qttools, qtx11extras, stdenv }:
   2
   3 mkDerivation rec {
   4   pname = "notepad-next";
   5   version = "0.7";
   6
   7   src = fetchFromGitHub {
   8     owner = "dail8859";
   9     repo = "NotepadNext";
  10     rev = "v${version}";
  11     sha256 = "sha256-I2bS8oT/TGf6fuXpTwOKo2MaUo0jLFIU/DfW9h1toOk=";
  12     # External dependencies - https://github.com/dail8859/NotepadNext/issues/135
  13     fetchSubmodules = true;
  14   };
  15
  16   nativeBuildInputs = [ qmake qttools ];
  17   buildInputs = [ qtx11extras ];
  18
  19   qmakeFlags = [
  20     "PREFIX=${placeholder "out"}"
  21     "src/NotepadNext.pro"
  22   ];
  23
  24   postPatch = ''
  25     substituteInPlace src/i18n.pri \
  26       --replace 'EXTRA_TRANSLATIONS = \' "" \
  27       --replace '$$[QT_INSTALL_TRANSLATIONS]/qt_zh_CN.qm' ""
  28   '';
  29
  30   postInstall = lib.optionalString stdenv.isDarwin ''
  31     mv $out/bin $out/Applications
  32     rm -fr $out/share
  33   '';
  34
  35   meta = with lib; {
  36     homepage = "https://github.com/dail8859/NotepadNext";
  37     description = "A cross-platform, reimplementation of Notepad++";
  38     license = licenses.gpl3Plus;
  39     platforms = platforms.unix;
  40     maintainers = [ maintainers.sebtm ];
  41     broken = stdenv.isAarch64;
  42     mainProgram = "NotepadNext";
  43   };
  44 }