pkgs/applications/emulators/wine/packages.nix

   1 { stdenv_32bit, lib, pkgs, pkgsi686Linux, pkgsCross, callPackage, substituteAll, moltenvk,
   2   wineRelease ? "stable",
   3   supportFlags
   4 }:
   5
   6 let
   7   src = lib.getAttr wineRelease (callPackage ./sources.nix {});
   8 in with src; {
   9   wine32 = pkgsi686Linux.callPackage ./base.nix {
  10     pname = "wine";
  11     inherit src version supportFlags patches moltenvk wineRelease;
  12     pkgArches = [ pkgsi686Linux ];
  13     geckos = [ gecko32 ];
  14     mingwGccs = with pkgsCross; [ mingw32.buildPackages.gcc ];
  15     monos =  [ mono ];
  16     platforms = [ "i686-linux" "x86_64-linux" ];
  17   };
  18   wine64 = callPackage ./base.nix {
  19     pname = "wine64";
  20     inherit src version supportFlags patches moltenvk wineRelease;
  21     pkgArches = [ pkgs ];
  22     mingwGccs = with pkgsCross; [ mingwW64.buildPackages.gcc ];
  23     geckos = [ gecko64 ];
  24     monos =  [ mono ];
  25     configureFlags = [ "--enable-win64" ];
  26     platforms = [ "x86_64-linux" "x86_64-darwin" ];
  27     mainProgram = "wine64";
  28   };
  29   wineWow = callPackage ./base.nix {
  30     pname = "wine-wow";
  31     inherit src version supportFlags patches moltenvk wineRelease;
  32     stdenv = stdenv_32bit;
  33     pkgArches = [ pkgs pkgsi686Linux ];
  34     geckos = [ gecko32 gecko64 ];
  35     mingwGccs = with pkgsCross; [ mingw32.buildPackages.gcc mingwW64.buildPackages.gcc ];
  36     monos =  [ mono ];
  37     buildScript = substituteAll {
  38         src = ./builder-wow.sh;
  39         # pkgconfig has trouble picking the right architecture
  40         pkgconfig64remove = lib.makeSearchPathOutput "dev" "lib/pkgconfig" [ pkgs.glib pkgs.gst_all_1.gstreamer ];
  41       };
  42     platforms = [ "x86_64-linux" ];
  43     mainProgram = "wine64";
  44   };
  45   wineWow64 = callPackage ./base.nix {
  46     pname = "wine-wow64";
  47     inherit src version patches moltenvk wineRelease;
  48     supportFlags = supportFlags // { mingwSupport = true; };  # Required because we request "--enable-archs=x86_64"
  49     pkgArches = [ pkgs ];
  50     mingwGccs = with pkgsCross; [ mingw32.buildPackages.gcc mingwW64.buildPackages.gcc ];
  51     geckos = [ gecko64 ];
  52     monos =  [ mono ];
  53     configureFlags = [ "--enable-archs=x86_64,i386" ];
  54     platforms = [ "x86_64-linux" "x86_64-darwin" ];
  55     mainProgram = "wine";
  56   };
  57 }