pkgs/applications/finance/irpf/default.nix

   1 { lib
   2 , stdenvNoCC
   3 , fetchzip
   4 , copyDesktopItems
   5 , jdk11
   6 , makeDesktopItem
   7 , makeWrapper
   8 , unzip
   9 , xdg-utils
  10 }:
  11
  12 stdenvNoCC.mkDerivation rec {
  13   pname = "irpf";
  14   version = "2024-1.0";
  15
  16   # https://www.gov.br/receitafederal/pt-br/centrais-de-conteudo/download/pgd/dirpf
  17   # Para outros sistemas operacionais -> Multi
  18   src = let
  19     year = lib.head (lib.splitVersion version);
  20   in fetchzip {
  21     url = "https://downloadirpf.receita.fazenda.gov.br/irpf/${year}/irpf/arquivos/IRPF${version}.zip";
  22     hash = "sha256-x47Ud/aSfPuZYMZSGhJLnNFtNE62I+WjaFFatJPMPYg=";
  23   };
  24
  25   nativeBuildInputs = [ unzip makeWrapper copyDesktopItems ];
  26
  27   desktopItems = [
  28     (makeDesktopItem {
  29       name = pname;
  30       exec = pname;
  31       icon = "rfb64";
  32       desktopName = "Imposto de Renda Pessoa Física";
  33       comment = "Programa Oficial da Receita para elaboração do IRPF";
  34       categories = [ "Office" ];
  35     })
  36   ];
  37
  38   installPhase = ''
  39     runHook preInstall
  40
  41     BASEDIR="$out/share/${pname}"
  42     mkdir -p "$BASEDIR"
  43
  44     cp --no-preserve=mode -r help lib lib-modulos "$BASEDIR"
  45
  46     install -Dm644 irpf.jar Leia-me.htm offline.png online.png pgd-updater.jar "$BASEDIR"
  47
  48     # make xdg-open overrideable at runtime
  49     makeWrapper ${jdk11}/bin/java $out/bin/${pname} \
  50       --add-flags "-Dawt.useSystemAAFontSettings=on" \
  51       --add-flags "-Dswing.aatext=true" \
  52       --add-flags "-jar $BASEDIR/${pname}.jar" \
  53       --suffix PATH : ${lib.makeBinPath [ xdg-utils ]} \
  54       --set _JAVA_AWT_WM_NONREPARENTING 1 \
  55       --set AWT_TOOLKIT MToolkit
  56
  57     mkdir -p $out/share/pixmaps
  58     unzip -j lib/ppgd-icones-4.0.jar icones/rfb64.png -d $out/share/pixmaps
  59
  60     runHook postInstall
  61   '';
  62
  63   meta = with lib; {
  64     description = "Brazillian government application for reporting income tax";
  65     longDescription = ''
  66       Brazillian government application for reporting income tax.
  67
  68       IRFP - Imposto de Renda Pessoa Física - Receita Federal do Brasil.
  69     '';
  70     homepage = "https://www.gov.br/receitafederal/pt-br";
  71     license = licenses.unfree;
  72     platforms = platforms.all;
  73     sourceProvenance = with sourceTypes; [ binaryBytecode ];
  74     maintainers = with maintainers; [ atila ];
  75     mainProgram = "irpf";
  76   };
  77 }