pkgs/applications/graphics/figma-linux/default.nix

   1 { pkgs
   2 , lib
   3 , stdenv
   4 , fetchurl
   5 , autoPatchelfHook
   6 , dpkg
   7 , wrapGAppsHook
   8 , ...
   9 }:
  10 with lib;
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "figma-linux";
  13   version = "0.11.3";
  14
  15   src = fetchurl {
  16     url = "https://github.com/Figma-Linux/figma-linux/releases/download/v${finalAttrs.version}/figma-linux_${finalAttrs.version}_linux_amd64.deb";
  17     hash = "sha256-9UfyCqgsg9XAFyZ7V7TogkQou4x+ixFUfjXZ1/qlDmA=";
  18   };
  19
  20   nativeBuildInputs = [ autoPatchelfHook dpkg wrapGAppsHook ];
  21
  22   buildInputs = with pkgs;[
  23     alsa-lib
  24     at-spi2-atk
  25     cairo
  26     cups.lib
  27     dbus.lib
  28     expat
  29     gdk-pixbuf
  30     glib
  31     gtk3
  32     libdrm
  33     libxkbcommon
  34     mesa
  35     nspr
  36     nss
  37     pango
  38   ] ++ (with pkgs.xorg; [
  39     libX11
  40     libXcomposite
  41     libXdamage
  42     libXext
  43     libXfixes
  44     libXrandr
  45     libxcb
  46     libxshmfence
  47   ]);
  48
  49   runtimeDependencies = with pkgs; [ eudev ];
  50
  51   unpackCmd = "dpkg -x $src .";
  52
  53   sourceRoot = ".";
  54
  55   installPhase = ''
  56     runHook preInstall
  57
  58     mkdir -p $out/lib && cp -r opt/figma-linux/* $_
  59     mkdir -p $out/bin && ln -s $out/lib/figma-linux $_/figma-linux
  60
  61     cp -r usr/* $out
  62
  63     runHook postInstall
  64   '';
  65
  66   postFixup = ''
  67     substituteInPlace $out/share/applications/figma-linux.desktop \
  68           --replace "Exec=/opt/figma-linux/figma-linux" "Exec=$out/bin/${finalAttrs.pname}"
  69   '';
  70
  71   meta = {
  72     description = "Unofficial Electron-based Figma desktop app for Linux";
  73     homepage = "https://github.com/Figma-Linux/figma-linux";
  74     platforms = [ "x86_64-linux" ];
  75     license = licenses.gpl2Plus;
  76     maintainers = with maintainers; [ ercao kashw2 ];
  77     mainProgram = "figma-linux";
  78   };
  79 })