pkgs/applications/graphics/imgbrd-grabber/default.nix

   1 { lib
   2 , stdenv
   3 , cmake
   4 , fetchFromGitHub
   5 , wrapQtAppsHook
   6 , qtmultimedia
   7 , qttools
   8 , qtdeclarative
   9 , qtnetworkauth
  10 , qtbase
  11 , makeWrapper
  12 , catch2
  13 , nodejs
  14 , libpulseaudio
  15 , openssl
  16 , rsync
  17 , typescript
  18 }:
  19
  20 stdenv.mkDerivation rec {
  21   pname = "imgbrd-grabber";
  22   version = "7.10.0";
  23
  24   src = fetchFromGitHub {
  25     owner = "Bionus";
  26     repo = "imgbrd-grabber";
  27     rev = "v${version}";
  28     sha256 = "sha256-AT6pN2do0LlH6xAXKcFQv+oderD88/EiG1JnCw6kOOg=";
  29     fetchSubmodules = true;
  30   };
  31
  32   buildInputs = [
  33     openssl
  34     libpulseaudio
  35     typescript
  36   ];
  37
  38   nativeBuildInputs = [
  39     makeWrapper
  40     qtmultimedia
  41     qtbase
  42     qtdeclarative
  43     qttools
  44     qtnetworkauth
  45     nodejs
  46     cmake
  47     wrapQtAppsHook
  48   ];
  49
  50   extraOutputsToLink = [ "doc" ];
  51
  52   postPatch = ''
  53     # the package.sh script provides some install helpers
  54     # using this might make it easier to maintain/less likely for the
  55     # install phase to fail across version bumps
  56     patchShebangs ./scripts/package.sh
  57
  58     # ensure the script uses the rsync package from nixpkgs
  59     substituteInPlace ../scripts/package.sh --replace "rsync" "${rsync}/bin/rsync"
  60
  61
  62     # the npm build step only runs typescript
  63     # run this step directly so it doesn't try and fail to download the unnecessary node_modules, etc.
  64     substituteInPlace ./sites/CMakeLists.txt --replace "npm install" "npm run build"
  65
  66     # remove the vendored catch2
  67     rm -rf tests/src/vendor/catch
  68
  69     # link the catch2 sources from nixpkgs
  70     ln -sf ${catch2.src} tests/src/vendor/catch
  71   '';
  72
  73   preBuild = ''
  74     export HOME=$TMPDIR
  75   '';
  76
  77   postInstall = ''
  78     # move the binaries to the share/Grabber folder so
  79     # some relative links can be resolved (e.g. settings.ini)
  80     mv $out/bin/* $out/share/Grabber/
  81
  82     cd ../..
  83     # run the package.sh with $out/share/Grabber as the $APP_DIR
  84     sh ./scripts/package.sh $out/share/Grabber
  85
  86     # add symlinks for the binaries to $out/bin
  87     ln -s $out/share/Grabber/Grabber $out/bin/Grabber
  88     ln -s $out/share/Grabber/Grabber-cli $out/bin/Grabber-cli
  89   '';
  90
  91   sourceRoot = "${src.name}/src";
  92
  93   meta = with lib; {
  94     description = "Very customizable imageboard/booru downloader with powerful filenaming features";
  95     license = licenses.asl20;
  96     homepage = "https://bionus.github.io/imgbrd-grabber/";
  97     mainProgram = "Grabber";
  98     maintainers = [ maintainers.evanjs ];
  99   };
 100 }