pkgs/applications/graphics/ocrfeeder/default.nix

   1 { lib, stdenv
   2 , fetchurl
   3 , pkg-config
   4 , wrapGAppsHook
   5 , intltool
   6 , itstool
   7 , libxml2
   8 , gobject-introspection
   9 , gtk3
  10 , goocanvas2
  11 , gtkspell3
  12 , isocodes
  13 , gnome
  14 , python3
  15 , tesseract4
  16 , extraOcrEngines ? [] # other supported engines are: ocrad gocr cuneiform
  17 }:
  18
  19 stdenv.mkDerivation (finalAttrs: {
  20   pname = "ocrfeeder";
  21   version = "0.8.5";
  22
  23   src = fetchurl {
  24     url = "mirror://gnome/sources/${finalAttrs.pname}/${lib.versions.majorMinor finalAttrs.version}/${finalAttrs.pname}-${finalAttrs.version}.tar.xz";
  25     sha256 = "sha256-sD0qWUndguJzTw0uy0FIqupFf4OX6dTFvcd+Mz+8Su0=";
  26   };
  27
  28   nativeBuildInputs = [
  29     pkg-config
  30     wrapGAppsHook
  31     intltool
  32     itstool
  33     libxml2
  34     gobject-introspection
  35   ];
  36
  37   buildInputs = [
  38     gtk3
  39     goocanvas2
  40     gtkspell3
  41     isocodes
  42     (python3.withPackages(ps: with ps; [
  43       pyenchant
  44       sane
  45       pillow
  46       reportlab
  47       odfpy
  48       pygobject3
  49     ]))
  50   ];
  51   patches = [
  52     # Compiles, but doesn't launch without this, see:
  53     # https://gitlab.gnome.org/GNOME/ocrfeeder/-/issues/83
  54     ./fix-launch.diff
  55   ];
  56
  57   enginesPath = lib.makeBinPath ([
  58     tesseract4
  59   ] ++ extraOcrEngines);
  60
  61   preFixup = ''
  62     gappsWrapperArgs+=(--prefix PATH : "${finalAttrs.enginesPath}")
  63     gappsWrapperArgs+=(--set ISO_CODES_DIR "${isocodes}/share/xml/iso-codes")
  64   '';
  65
  66   meta = with lib; {
  67     homepage = "https://wiki.gnome.org/Apps/OCRFeeder";
  68     description = "Complete Optical Character Recognition and Document Analysis and Recognition program";
  69     maintainers = with maintainers; [ doronbehar ];
  70     license = licenses.gpl3Plus;
  71     platforms = platforms.linux;
  72   };
  73 })