pkgs/applications/misc/archivy/default.nix

   1 { lib
   2 , python3
   3 , fetchPypi
   4 }:
   5
   6 let
   7   py = python3.override {
   8     packageOverrides = self: super: {
   9       wtforms = super.wtforms.overridePythonAttrs (oldAttrs: rec {
  10         version = "2.3.1";
  11
  12         src = oldAttrs.src.override {
  13           inherit version;
  14           sha256 = "sha256-hhoTs65SHWcA2sOydxlwvTVKY7pwQ+zDqCtSiFlqGXI=";
  15         };
  16
  17         doCheck = false;
  18       });
  19     };
  20   };
  21 in
  22 with py.pkgs;
  23
  24 buildPythonApplication rec {
  25   pname = "archivy";
  26   version = "1.7.3";
  27   format = "setuptools";
  28
  29   src = fetchPypi {
  30     inherit pname version;
  31     hash = "sha256-ns1Y0DqqnTAQMEt+oBJ/P2gqKqPsX9P3/Z4561qzuns";
  32   };
  33
  34   nativeBuildInputs = [ pythonRelaxDepsHook ];
  35
  36   pythonRelaxDeps = true;
  37
  38   propagatedBuildInputs = [
  39     appdirs
  40     attrs
  41     beautifulsoup4
  42     click-plugins
  43     elasticsearch
  44     flask-compress
  45     flask-login
  46     flask-wtf
  47     html2text
  48     python-dotenv
  49     python-frontmatter
  50     readability-lxml
  51     requests
  52     setuptools
  53     tinydb
  54     validators
  55     wtforms
  56   ];
  57
  58   # __init__.py attempts to mkdir in read-only file system
  59   doCheck = false;
  60
  61   meta = with lib; {
  62     description = "Self-hosted knowledge repository";
  63     homepage = "https://archivy.github.io";
  64     license = licenses.mit;
  65     maintainers = with maintainers; [ siraben ];
  66     platforms = platforms.unix;
  67   };
  68 }