pkgs/applications/misc/gkrellm/default.nix

   1 { lib
   2 , fetchurl
   3 , stdenv
   4 , gettext
   5 , pkg-config
   6 , glib
   7 , gtk2
   8 , libX11
   9 , libSM
  10 , libICE
  11 , which
  12 , IOKit
  13 , copyDesktopItems
  14 , makeDesktopItem
  15 , wrapGAppsHook
  16 }:
  17
  18 stdenv.mkDerivation rec {
  19   pname = "gkrellm";
  20   version = "2.3.11";
  21
  22   src = fetchurl {
  23     url = "http://gkrellm.srcbox.net/releases/gkrellm-${version}.tar.bz2";
  24     sha256 = "01lccz4fga40isv09j8rjgr0qy10rff9vj042n6gi6gdv4z69q0y";
  25   };
  26
  27   nativeBuildInputs = [ copyDesktopItems pkg-config which wrapGAppsHook ];
  28   buildInputs = [ gettext glib gtk2 libX11 libSM libICE ]
  29     ++ lib.optionals stdenv.isDarwin [ IOKit ];
  30
  31   hardeningDisable = [ "format" ];
  32
  33   # Makefiles are patched to fix references to `/usr/X11R6' and to add
  34   # `-lX11' to make sure libX11's store path is in the RPATH.
  35   postPatch = ''
  36     echo "patching makefiles..."
  37     for i in Makefile src/Makefile server/Makefile
  38     do
  39       sed -i "$i" -e "s|/usr/X11R6|${libX11.dev}|g ; s|-lICE|-lX11 -lICE|g"
  40     done
  41   '';
  42
  43   makeFlags = [ "STRIP=-s" ];
  44   installFlags = [ "DESTDIR=$(out)" ];
  45
  46   # This icon is used by the desktop file.
  47   postInstall = ''
  48     install -Dm444 -T src/icon.xpm $out/share/pixmaps/gkrellm.xpm
  49   '';
  50
  51   desktopItems = [
  52     (makeDesktopItem {
  53       name = "gkrellm";
  54       exec = "gkrellm";
  55       icon = "gkrellm";
  56       desktopName = "GKrellM";
  57       genericName = "System monitor";
  58       comment = "The GNU Krell Monitors";
  59       categories = [ "System" "Monitor" ];
  60     })
  61   ];
  62
  63   meta = with lib; {
  64     description = "Themeable process stack of system monitors";
  65     longDescription = ''
  66       GKrellM is a single process stack of system monitors which
  67       supports applying themes to match its appearance to your window
  68       manager, Gtk, or any other theme.
  69     '';
  70
  71     homepage = "http://gkrellm.srcbox.net";
  72     license = licenses.gpl3Plus;
  73     maintainers = with maintainers; [ khumba ];
  74     platforms = platforms.linux;
  75   };
  76 }