pkgs/applications/misc/pueue/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , Libsystem
   5 , SystemConfiguration
   6 , installShellFiles
   7 , libiconv
   8 , rustPlatform
   9 }:
  10
  11 rustPlatform.buildRustPackage rec {
  12   pname = "pueue";
  13   version = "3.4.0";
  14
  15   src = fetchFromGitHub {
  16     owner = "Nukesor";
  17     repo = "pueue";
  18     rev = "v${version}";
  19     hash = "sha256-kKu/+F+zK0UyRHGkrZdD8alvsQTZFHhTqYK2phxo/ZA=";
  20   };
  21
  22   cargoHash = "sha256-KwIGJiCGcFEKuloVtJr0GQxoFQVt/OHyJ/YCp4bCSGc=";
  23
  24   nativeBuildInputs = [
  25     installShellFiles
  26   ] ++ lib.optionals stdenv.isDarwin [
  27     rustPlatform.bindgenHook
  28   ];
  29
  30   buildInputs = lib.optionals stdenv.isDarwin [
  31     Libsystem
  32     SystemConfiguration
  33     libiconv
  34   ];
  35
  36   checkFlags = [
  37     "--test client_tests"
  38     "--skip=test_single_huge_payload"
  39     "--skip=test_create_unix_socket"
  40   ];
  41
  42   postInstall = ''
  43     for shell in bash fish zsh; do
  44       $out/bin/pueue completions $shell .
  45     done
  46     installShellCompletion pueue.{bash,fish} _pueue
  47   '';
  48
  49   meta = with lib; {
  50     homepage = "https://github.com/Nukesor/pueue";
  51     description = "A daemon for managing long running shell commands";
  52     longDescription = ''
  53       Pueue is a command-line task management tool for sequential and parallel
  54       execution of long-running tasks.
  55
  56       Simply put, it's a tool that processes a queue of shell commands. On top
  57       of that, there are a lot of convenient features and abstractions.
  58
  59       Since Pueue is not bound to any terminal, you can control your tasks from
  60       any terminal on the same machine. The queue will be continuously
  61       processed, even if you no longer have any active ssh sessions.
  62     '';
  63     changelog = "https://github.com/Nukesor/pueue/blob/v${version}/CHANGELOG.md";
  64     license = licenses.mit;
  65     maintainers = with maintainers; [ marsam ];
  66   };
  67 }