pkgs/applications/misc/streamdeck-ui/default.nix

   1 { lib
   2 , python3Packages
   3 , fetchFromGitHub
   4 , copyDesktopItems
   5 , writeText
   6 , makeDesktopItem
   7 , wrapGAppsHook
   8 , xvfb-run
   9 , qt6
  10 }:
  11
  12 python3Packages.buildPythonApplication rec {
  13   pname = "streamdeck-ui";
  14   version = "3.1.0";
  15
  16   src = fetchFromGitHub {
  17     repo = "streamdeck-linux-gui";
  18     owner = "streamdeck-linux-gui";
  19     rev = "v${version}";
  20     sha256 = "sha256-AIE9j022L4WSlHBAu3TT5uE4Ilgk/jYSmU03K8Hs8xY=";
  21   };
  22
  23   patches = [
  24     # nixpkgs has a newer pillow version
  25     ./update-pillow.patch
  26   ];
  27
  28   desktopItems = let
  29     common = {
  30       name = "streamdeck-ui";
  31       desktopName = "Stream Deck UI";
  32       icon = "streamdeck-ui";
  33       exec = "streamdeck";
  34       comment = "UI for the Elgato Stream Deck";
  35       categories = [ "Utility" ];
  36     };
  37   in builtins.map makeDesktopItem [
  38     common
  39     (common // {
  40       name = "${common.name}-noui";
  41       exec = "${common.exec} --no-ui";
  42       noDisplay = true;
  43     })
  44   ];
  45
  46   postInstall =
  47     let
  48       udevRules = ''
  49         SUBSYSTEM=="usb", ATTRS{idVendor}=="0fd9", TAG+="uaccess"
  50       '';
  51     in
  52       ''
  53         mkdir -p $out/lib/systemd/user
  54         substitute scripts/streamdeck.service $out/lib/systemd/user/streamdeck.service \
  55           --replace '<path to streamdeck>' $out/bin/streamdeck
  56
  57         mkdir -p "$out/etc/udev/rules.d"
  58         cp ${writeText "70-streamdeck.rules" udevRules} $out/etc/udev/rules.d/70-streamdeck.rules
  59
  60         mkdir -p "$out/share/pixmaps"
  61         cp streamdeck_ui/logo.png $out/share/pixmaps/streamdeck-ui.png
  62       '';
  63
  64   dontWrapQtApps = true;
  65   dontWrapGApps = true;
  66   makeWrapperArgs = [ "\${qtWrapperArgs[@]}" "\${gappsWrapperArgs[@]}"];
  67
  68   format = "pyproject";
  69
  70   nativeBuildInputs = [
  71     python3Packages.poetry-core
  72     copyDesktopItems
  73     qt6.wrapQtAppsHook
  74     wrapGAppsHook
  75   ];
  76
  77   propagatedBuildInputs = with python3Packages; [
  78     setuptools
  79     filetype
  80     cairosvg
  81     pillow
  82     pynput
  83     pyside6
  84     streamdeck
  85     xlib
  86   ] ++ lib.optionals stdenv.isLinux [
  87     qt6.qtwayland
  88   ];
  89
  90   nativeCheckInputs = [
  91     xvfb-run
  92     python3Packages.pytest
  93   ];
  94
  95   checkPhase = ''
  96     xvfb-run pytest tests
  97   '';
  98
  99   meta = with lib; {
 100     description = "Linux compatible UI for the Elgato Stream Deck";
 101     homepage = "https://streamdeck-linux-gui.github.io/streamdeck-linux-gui/";
 102     license = licenses.mit;
 103     mainProgram = "streamdeck";
 104     maintainers = with maintainers; [ majiir ];
 105   };
 106 }