pkgs/applications/misc/tuxclocker/default.nix

   1 { lib
   2 , stdenv
   3 , boost
   4 , fetchFromGitHub
   5 , git
   6 , makeWrapper
   7 , meson
   8 , ninja
   9 , pkg-config
  10 , python3
  11 , qtbase
  12 , qtcharts
  13 , tuxclocker-plugins
  14 , tuxclocker-without-unfree
  15 , wrapQtAppsHook
  16 }:
  17
  18 stdenv.mkDerivation (finalAttrs: {
  19   pname = "tuxclocker";
  20   version = "1.5.1";
  21
  22   src = fetchFromGitHub {
  23     owner = "Lurkki14";
  24     repo = "tuxclocker";
  25     fetchSubmodules = true;
  26     rev = finalAttrs.version;
  27     hash = "sha256-QLKLqTCpVMWxlDINa8Bo1vgCDcjwovoaXUs/PdMnxv0=";
  28   };
  29
  30   # Meson doesn't find boost without these
  31   BOOST_INCLUDEDIR = "${lib.getDev boost}/include";
  32   BOOST_LIBRARYDIR = "${lib.getLib boost}/lib";
  33
  34   nativeBuildInputs = [
  35     git
  36     makeWrapper
  37     meson
  38     ninja
  39     pkg-config
  40     wrapQtAppsHook
  41   ];
  42
  43   buildInputs = [
  44     boost
  45     qtbase
  46     qtcharts
  47   ];
  48
  49   postInstall = ''
  50     wrapProgram "$out/bin/tuxclockerd" \
  51       --prefix "TEXTDOMAINDIR" : "${tuxclocker-plugins}/share/locale" \
  52       --prefix "TUXCLOCKER_PLUGIN_PATH" : "${tuxclocker-plugins}/lib/tuxclocker/plugins" \
  53       --prefix "PYTHONPATH" : "${python3.pkgs.hwdata}/${python3.sitePackages}"
  54   '';
  55
  56   mesonFlags = [
  57     "-Dplugins=false"
  58   ];
  59
  60   passthru.tests = {
  61     inherit tuxclocker-without-unfree;
  62   };
  63
  64   meta = with lib; {
  65     description = "Qt overclocking tool for GNU/Linux";
  66     homepage = "https://github.com/Lurkki14/tuxclocker";
  67     license = licenses.gpl3Only;
  68     maintainers = with maintainers; [ lurkki ];
  69     platforms = platforms.linux;
  70   };
  71 })