pkgs/applications/networking/instant-messengers/discord/darwin.nix

   1 { pname, version, src, meta, stdenv, binaryName, desktopName, lib, undmg, makeWrapper, writeScript
   2 , branch
   3 , withOpenASAR ? false, openasar
   4 , withVencord ? false, vencord }:
   5
   6 stdenv.mkDerivation {
   7   inherit pname version src meta;
   8
   9   nativeBuildInputs = [ undmg makeWrapper ];
  10
  11   sourceRoot = ".";
  12
  13   installPhase = ''
  14     runHook preInstall
  15
  16     mkdir -p $out/Applications
  17     cp -r "${desktopName}.app" $out/Applications
  18
  19     # wrap executable to $out/bin
  20     mkdir -p $out/bin
  21     makeWrapper "$out/Applications/${desktopName}.app/Contents/MacOS/${binaryName}" "$out/bin/${binaryName}"
  22
  23     runHook postInstall
  24   '';
  25
  26   postInstall = lib.strings.optionalString withOpenASAR ''
  27     cp -f ${openasar} $out/Applications/${desktopName}.app/Contents/Resources/app.asar
  28   '' + lib.strings.optionalString withVencord ''
  29     mv $out/Applications/${desktopName}.app/Contents/Resources/app.asar $out/Applications/${desktopName}.app/Contents/Resources/_app.asar
  30     mkdir $out/Applications/${desktopName}.app/Contents/Resources/app.asar
  31     echo '{"name":"discord","main":"index.js"}' > $out/Applications/${desktopName}.app/Contents/Resources/app.asar/package.json
  32     echo 'require("${vencord}/patcher.js")' > $out/Applications/${desktopName}.app/Contents/Resources/app.asar/index.js
  33   '';
  34
  35   passthru = {
  36     updateScript = writeScript "discord-update-script" ''
  37       #!/usr/bin/env nix-shell
  38       #!nix-shell -i bash -p curl gnugrep common-updater-scripts
  39       set -x
  40       set -eou pipefail;
  41       url=$(curl -sI "https://discordapp.com/api/download/${
  42         builtins.replaceStrings [ "discord-" "discord" ] [ "" "stable" ] pname
  43       }?platform=osx&format=dmg" | grep -oP 'location: \K\S+')
  44       version=''${url##https://dl*.discordapp.net/apps/osx/}
  45       version=''${version%%/*.dmg}
  46       update-source-version ${lib.optionalString (!stdenv.buildPlatform.isDarwin) "pkgsCross.aarch64-darwin."}${pname} "$version" --file=./pkgs/applications/networking/instant-messengers/discord/default.nix --version-key=${branch}
  47     '';
  48   };
  49 }