pkgs/applications/networking/instant-messengers/gajim/default.nix

   1 { lib, fetchurl, fetchFromGitLab, gettext, wrapGAppsHook
   2
   3 # Native dependencies
   4 , python3, gtk3, gobject-introspection, gnome
   5 , gtksourceview4
   6 , glib-networking
   7
   8 # Test dependencies
   9 , xvfb-run, dbus
  10
  11 # Optional dependencies
  12 , enableJingle ? true, farstream, gstreamer, gst-plugins-base, gst-libav, gst-plugins-good, libnice
  13 , enableE2E ? true
  14 , enableSecrets ? true, libsecret
  15 , enableRST ? true, docutils
  16 , enableSpelling ? true, gspell
  17 , enableUPnP ? true, gupnp-igd
  18 , enableAppIndicator ? true, libappindicator-gtk3
  19 , extraPythonPackages ? ps: []
  20 }:
  21
  22 python3.pkgs.buildPythonApplication rec {
  23   pname = "gajim";
  24   version = "1.8.4";
  25
  26   src = fetchurl {
  27     url = "https://gajim.org/downloads/${lib.versions.majorMinor version}/gajim-${version}.tar.gz";
  28     hash = "sha256-WPzth7HOAbPVJpvN8zSZJGUzsBtACNlwHrHhDPlOScU=";
  29   };
  30
  31   format = "pyproject";
  32
  33   buildInputs = [
  34     gtk3 gnome.adwaita-icon-theme
  35     gtksourceview4
  36     glib-networking
  37   ] ++ lib.optionals enableJingle [ farstream gstreamer gst-plugins-base gst-libav gst-plugins-good libnice ]
  38     ++ lib.optional enableSecrets libsecret
  39     ++ lib.optional enableSpelling gspell
  40     ++ lib.optional enableUPnP gupnp-igd
  41     ++ lib.optional enableAppIndicator libappindicator-gtk3;
  42
  43   nativeBuildInputs = [
  44     gettext wrapGAppsHook gobject-introspection
  45   ];
  46
  47   dontWrapGApps = true;
  48
  49   preFixup = ''
  50     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  51   '';
  52
  53   propagatedBuildInputs = with python3.pkgs; [
  54     nbxmpp pygobject3 dbus-python pillow css-parser precis-i18n keyring setuptools packaging gssapi
  55     omemo-dr qrcode
  56   ] ++ lib.optionals enableE2E [ pycrypto python-gnupg ]
  57     ++ lib.optional enableRST docutils
  58     ++ extraPythonPackages python3.pkgs;
  59
  60   nativeCheckInputs = [ xvfb-run dbus ];
  61
  62   preBuild = ''
  63     python pep517build/build_metadata.py -o dist/metadata
  64   '';
  65
  66   postInstall = ''
  67     python pep517build/install_metadata.py dist/metadata --prefix=$out
  68   '';
  69
  70   checkPhase = ''
  71     xvfb-run dbus-run-session \
  72       --config-file=${dbus}/share/dbus-1/session.conf \
  73       ${python3.interpreter} -m unittest discover -s test/gui -v
  74     ${python3.interpreter} -m unittest discover -s test/common -v
  75   '';
  76
  77   # test are broken in 1.7.3, 1.8.0
  78   doCheck = false;
  79
  80   # necessary for wrapGAppsHook
  81   strictDeps = false;
  82
  83   meta = {
  84     homepage = "http://gajim.org/";
  85     description = "Jabber client written in PyGTK";
  86     license = lib.licenses.gpl3Plus;
  87     maintainers = with lib.maintainers; [ raskin abbradar ];
  88     downloadPage = "http://gajim.org/download/";
  89     platforms = lib.platforms.linux;
  90     mainProgram = "gajim";
  91   };
  92 }