pkgs/applications/networking/instant-messengers/teams-for-linux/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , makeWrapper
   5 , makeDesktopItem
   6 , copyDesktopItems
   7 , yarn
   8 , nodejs
   9 , fetchYarnDeps
  10 , fixup-yarn-lock
  11 , electron
  12 , alsa-utils
  13 , which
  14 , testers
  15 , teams-for-linux
  16 }:
  17
  18 stdenv.mkDerivation (finalAttrs: {
  19   pname = "teams-for-linux";
  20   version = "1.4.27";
  21
  22   src = fetchFromGitHub {
  23     owner = "IsmaelMartinez";
  24     repo = "teams-for-linux";
  25     rev = "v${finalAttrs.version}";
  26     hash = "sha256-nUHiveS1XI+vC2Tj1DK/DS4CrKTLMg1IYgTPWXuLrAc=";
  27   };
  28
  29   offlineCache = fetchYarnDeps {
  30     yarnLock = "${finalAttrs.src}/yarn.lock";
  31     hash = "sha256-jBwyIyiWeqNmOnxmVOr7c4oMWwHElEjM25sShhTMi78=";
  32   };
  33
  34   nativeBuildInputs = [ yarn fixup-yarn-lock nodejs copyDesktopItems makeWrapper ];
  35
  36   configurePhase = ''
  37     runHook preConfigure
  38
  39     export HOME=$(mktemp -d)
  40     yarn config --offline set yarn-offline-mirror $offlineCache
  41     fixup-yarn-lock yarn.lock
  42     yarn install --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive
  43     patchShebangs node_modules/
  44
  45     runHook postConfigure
  46   '';
  47
  48   buildPhase = ''
  49     runHook preBuild
  50
  51     yarn --offline electron-builder \
  52       --dir ${if stdenv.isDarwin then "--macos" else "--linux"} ${if stdenv.hostPlatform.isAarch64 then "--arm64" else "--x64"} \
  53       -c.electronDist=${electron}/libexec/electron \
  54       -c.electronVersion=${electron.version}
  55
  56     runHook postBuild
  57   '';
  58
  59   installPhase = ''
  60     runHook preInstall
  61
  62     mkdir -p $out/share/{applications,teams-for-linux}
  63     cp dist/${if stdenv.isDarwin then "darwin-" else "linux-"}${lib.optionalString stdenv.hostPlatform.isAarch64 "arm64-"}unpacked/resources/app.asar $out/share/teams-for-linux/
  64
  65     pushd build/icons
  66     for image in *png; do
  67       mkdir -p $out/share/icons/hicolor/''${image%.png}/apps
  68       cp -r $image $out/share/icons/hicolor/''${image%.png}/apps/teams-for-linux.png
  69     done
  70     popd
  71
  72     # Linux needs 'aplay' for notification sounds
  73     makeWrapper '${electron}/bin/electron' "$out/bin/teams-for-linux" \
  74       ${lib.optionalString stdenv.isLinux ''
  75         --prefix PATH : ${lib.makeBinPath [ alsa-utils which ]} \
  76       ''} \
  77       --add-flags "$out/share/teams-for-linux/app.asar" \
  78       --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}"
  79
  80     runHook postInstall
  81   '';
  82
  83   desktopItems = [(makeDesktopItem {
  84     name = finalAttrs.pname;
  85     exec = finalAttrs.pname;
  86     icon = finalAttrs.pname;
  87     desktopName = "Microsoft Teams for Linux";
  88     comment = finalAttrs.meta.description;
  89     categories = [ "Network" "InstantMessaging" "Chat" ];
  90   })];
  91
  92   passthru.updateScript = ./update.sh;
  93   passthru.tests.version = testers.testVersion rec {
  94     package = teams-for-linux;
  95     command = "HOME=$TMPDIR ${package.meta.mainProgram or package.pname} --version";
  96   };
  97
  98   meta = {
  99     description = "Unofficial Microsoft Teams client for Linux";
 100     mainProgram = "teams-for-linux";
 101     homepage = "https://github.com/IsmaelMartinez/teams-for-linux";
 102     license = lib.licenses.gpl3Only;
 103     maintainers = with lib.maintainers; [ muscaln lilyinstarlight qjoly chvp ];
 104     platforms = lib.platforms.unix;
 105     broken = stdenv.isDarwin;
 106   };
 107 })