pkgs/applications/networking/instant-messengers/zulip-term/default.nix

   1 { lib
   2 , python3
   3 , fetchFromGitHub
   4 , glibcLocales
   5 , libnotify
   6 }:
   7
   8 let
   9   py = python3.override {
  10     packageOverrides = self: super: {
  11
  12       # Requires "urwid~=2.1.2", otherwise some tests are failing
  13       urwid = super.urwid.overridePythonAttrs (oldAttrs: rec {
  14         version = "2.1.2";
  15         src = fetchFromGitHub {
  16           owner = "urwid";
  17           repo = "urwid";
  18           rev = "refs/tags/${version}";
  19           hash = "sha256-oPb2h/+gaqkZTXIiESjExMfBNnOzDvoMkXvkZ/+KVwo=";
  20         };
  21         doCheck = false;
  22       });
  23     };
  24   };
  25 in
  26 with py.pkgs;
  27
  28 buildPythonApplication rec {
  29   pname = "zulip-term";
  30   version = "0.7.0";
  31   pyproject = true;
  32
  33   src = fetchFromGitHub {
  34     owner = "zulip";
  35     repo = "zulip-terminal";
  36     rev = "refs/tags/${version}";
  37     hash = "sha256-ZouUU4p1FSGMxPuzDo5P971R+rDXpBdJn2MqvkJO+Fw=";
  38   };
  39
  40   patches = [
  41     ./pytest-executable-name.patch
  42   ];
  43
  44   nativeBuildInputs = with py.pkgs; [
  45     setuptools
  46   ];
  47
  48   propagatedBuildInputs = with py.pkgs; [
  49     beautifulsoup4
  50     lxml
  51     pygments
  52     pyperclip
  53     python-dateutil
  54     pytz
  55     typing-extensions
  56     tzlocal
  57     urwid
  58     urwid-readline
  59     zulip
  60   ];
  61
  62   nativeCheckInputs = [
  63     glibcLocales
  64   ] ++ (with python3.pkgs; [
  65     pytestCheckHook
  66     pytest-cov
  67     pytest-mock
  68   ]);
  69
  70   makeWrapperArgs = [
  71     "--prefix" "PATH" ":" (lib.makeBinPath [ libnotify ])
  72   ];
  73
  74   meta = with lib; {
  75     description = "Zulip's official terminal client";
  76     homepage = "https://github.com/zulip/zulip-terminal";
  77     changelog = "https://github.com/zulip/zulip-terminal/releases/tag/${version}";
  78     license = licenses.asl20;
  79     maintainers = with maintainers; [ dotlambda ];
  80   };
  81 }