pkgs/applications/networking/znc/default.nix

   1 { lib, stdenv, fetchurl, openssl, pkg-config
   2 , withPerl ? false, perl
   3 , withPython ? false, python3
   4 , withTcl ? false, tcl
   5 , withCyrus ? true, cyrus_sasl
   6 , withUnicode ? true, icu
   7 , withZlib ? true, zlib
   8 , withIPv6 ? true
   9 , withDebug ? false
  10 }:
  11
  12 stdenv.mkDerivation rec {
  13   pname = "znc";
  14   version = "1.8.2";
  15
  16   src = fetchurl {
  17     url = "https://znc.in/releases/archive/${pname}-${version}.tar.gz";
  18     sha256 = "03fyi0j44zcanj1rsdx93hkdskwfvhbywjiwd17f9q1a7yp8l8zz";
  19   };
  20
  21   nativeBuildInputs = [ pkg-config ];
  22
  23   buildInputs = [ openssl ]
  24     ++ lib.optional withPerl perl
  25     ++ lib.optional withPython python3
  26     ++ lib.optional withTcl tcl
  27     ++ lib.optional withCyrus cyrus_sasl
  28     ++ lib.optional withUnicode icu
  29     ++ lib.optional withZlib zlib;
  30
  31   configureFlags = [
  32     (lib.enableFeature withPerl "perl")
  33     (lib.enableFeature withPython "python")
  34     (lib.enableFeature withTcl "tcl")
  35     (lib.withFeatureAs withTcl "tcl" "${tcl}/lib")
  36     (lib.enableFeature withCyrus "cyrus")
  37   ] ++ lib.optionals (!withIPv6) [ "--disable-ipv6" ]
  38     ++ lib.optionals withDebug [ "--enable-debug" ];
  39
  40   enableParallelBuilding = true;
  41
  42   meta = with lib; {
  43     description = "Advanced IRC bouncer";
  44     homepage = "https://wiki.znc.in/ZNC";
  45     maintainers = with maintainers; [ schneefux lnl7 ];
  46     license = licenses.asl20;
  47     platforms = platforms.unix;
  48   };
  49 }