pkgs/applications/plasma-mobile/default.nix

   1 /*
   2
   3 # New packages
   4
   5 READ THIS FIRST
   6
   7 This module is for official packages in the Plasma Mobile Gear. All
   8 available packages are listed in `./srcs.nix`, although some are not yet
   9 packaged in Nixpkgs.
  10
  11 IF YOUR PACKAGE IS NOT LISTED IN `./srcs.nix`, IT DOES NOT GO HERE.
  12
  13 See also `pkgs/applications/kde` as this is what this is based on.
  14
  15 # Updates
  16
  17 1. Update the URL in `./fetch.sh`.
  18 2. Run `./maintainers/scripts/fetch-kde-qt.sh pkgs/applications/plasma-mobile`
  19    from the top of the Nixpkgs tree.
  20 3. Use `nox-review wip` to check that everything builds.
  21 4. Commit the changes and open a pull request.
  22
  23 */
  24
  25 { lib
  26 , libsForQt5
  27 , fetchurl
  28 }:
  29
  30 let
  31   mirror = "mirror://kde";
  32   srcs = import ./srcs.nix { inherit fetchurl mirror; };
  33
  34   mkDerivation = args:
  35     let
  36       inherit (args) pname;
  37       inherit (srcs.${pname}) src version;
  38       mkDerivation =
  39         libsForQt5.callPackage ({ mkDerivation }: mkDerivation) {};
  40     in
  41       mkDerivation (args // {
  42         inherit pname version src;
  43
  44         outputs = args.outputs or [ "out" ];
  45
  46         meta =
  47           let meta = args.meta or {}; in
  48           meta // {
  49             homepage = meta.homepage or "https://www.plasma-mobile.org/";
  50             platforms = meta.platforms or lib.platforms.linux;
  51           };
  52       });
  53
  54   packages = self:
  55     let
  56       callPackage = self.newScope {
  57         inherit mkDerivation;
  58       };
  59     in {
  60       plasma-dialer = callPackage ./plasma-dialer.nix {};
  61       plasma-phonebook = callPackage ./plasma-phonebook.nix {};
  62       plasma-settings = callPackage ./plasma-settings.nix {};
  63       spacebar = callPackage ./spacebar.nix {};
  64     };
  65
  66 in lib.makeScope libsForQt5.newScope packages