pkgs/applications/science/math/scilab-bin/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , makeWrapper
   5 , undmg
   6 , autoPatchelfHook
   7 , alsa-lib
   8 , ncurses5
   9 , xorg
  10 }:
  11
  12 let
  13   pname = "scilab-bin";
  14   version = "6.1.1";
  15
  16   srcs = {
  17     aarch64-darwin = fetchurl {
  18       url = "https://www.utc.fr/~mottelet/scilab/download/${version}/scilab-${version}-accelerate-arm64.dmg";
  19       sha256 = "sha256-L4dxD8R8bY5nd+4oDs5Yk0LlNsFykLnAM+oN/O87SRI=";
  20     };
  21     x86_64-darwin = fetchurl {
  22       url = "https://www.utc.fr/~mottelet/scilab/download/${version}/scilab-${version}-x86_64.dmg";
  23       sha256 = "sha256-tBeqzllMuogrGcJxGqEl2DdNXaiwok3yhzWSdlWY5Fc=";
  24     };
  25     x86_64-linux = fetchurl {
  26       url = "https://www.scilab.org/download/${version}/scilab-${version}.bin.linux-x86_64.tar.gz";
  27       sha256 = "sha256-PuGnz2YdAhriavwnuf5Qyy0cnCeRHlWC6dQzfr7bLHk=";
  28     };
  29   };
  30   src = srcs.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
  31
  32   meta = {
  33     homepage = "http://www.scilab.org/";
  34     description = "Scientific software package for numerical computations (Matlab lookalike)";
  35     platforms = [ "aarch64-darwin" "x86_64-darwin" "x86_64-linux" ];
  36     sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
  37     license = lib.licenses.gpl2Only;
  38     mainProgram = "scilab";
  39   };
  40
  41   darwin = stdenv.mkDerivation rec {
  42     inherit pname version src meta;
  43
  44     nativeBuildInputs = [
  45       makeWrapper
  46       undmg
  47     ];
  48
  49     sourceRoot = "scilab-${version}.app";
  50
  51     installPhase = ''
  52       runHook preInstall
  53
  54       mkdir -p $out/{Applications/scilab.app,bin}
  55       cp -R . $out/Applications/scilab.app
  56       makeWrapper $out/{Applications/scilab.app/Contents/MacOS,bin}/scilab
  57
  58       runHook postInstall
  59     '';
  60   };
  61
  62   linux = stdenv.mkDerivation rec {
  63     inherit pname version src meta;
  64
  65     nativeBuildInputs = [
  66       autoPatchelfHook
  67     ];
  68
  69     buildInputs = [
  70       alsa-lib
  71       ncurses5
  72       stdenv.cc.cc
  73     ] ++ (with xorg; [
  74       libX11
  75       libXcursor
  76       libXext
  77       libXft
  78       libXi
  79       libXrandr
  80       libXrender
  81       libXtst
  82       libXxf86vm
  83     ]);
  84
  85     installPhase = ''
  86       runHook preInstall
  87
  88       mkdir -p $out
  89       mv -t $out bin include lib share thirdparty
  90       sed -i \
  91         -e 's|\$(/bin/|$(|g' \
  92         -e 's|/usr/bin/||g' \
  93         $out/bin/{scilab,xcos}
  94       sed -i \
  95         -e "s|Exec=|Exec=$out/bin/|g" \
  96         -e "s|Terminal=.*$|Terminal=true|g" \
  97         $out/share/applications/*.desktop
  98
  99       runHook postInstall
 100     '';
 101   };
 102 in
 103 if stdenv.isDarwin then darwin else linux