pkgs/applications/video/anime-downloader/default.nix

   1 { lib, python3, aria2, mpv, nodejs, qt5, fetchFromGitHub }:
   2
   3 python3.pkgs.buildPythonApplication rec {
   4   pname = "anime-downloader";
   5   version = "5.0.14";
   6
   7   src = fetchFromGitHub {
   8     owner = "anime-dl";
   9     repo = "anime-downloader";
  10     rev = version;
  11     sha256 = "sha256-Uk2mtsSrb8fCD9JCFzvLBzMEB7ViVDrKPSOKy9ALJ6o=";
  12   };
  13
  14   nativeBuildInputs = [ qt5.wrapQtAppsHook ];
  15
  16   propagatedBuildInputs = [
  17     aria2
  18     mpv
  19     nodejs
  20   ] ++ (with python3.pkgs; [
  21     beautifulsoup4
  22     cfscrape
  23     click
  24     coloredlogs
  25     fuzzywuzzy
  26     jsbeautifier
  27     pycryptodome
  28     pysmartdl
  29     pyqt5
  30     requests
  31     requests-cache
  32     selenium
  33     tabulate
  34   ]);
  35
  36   preFixup = ''
  37     wrapQtApp "$out/bin/anime" --prefix PATH : ${lib.makeBinPath propagatedBuildInputs}
  38   '';
  39
  40   doCheck = false;
  41   # FIXME: checks must be disabled because they are lacking the qt env.
  42   #        They fail like this, even if built and wrapped with all Qt and runtime dependencies.
  43   #        Ref.: https://github.com/NixOS/nixpkgs/blob/634141959076a8ab69ca2cca0f266852256d79ee/pkgs/applications/misc/openlp/lib.nix#L20-L23
  44
  45   passthru.updateScript = ./update.sh;
  46
  47   meta = with lib; {
  48     homepage = "https://github.com/anime-dl/anime-downloader";
  49     description = "A simple but powerful anime downloader and streamer";
  50     license = licenses.unlicense;
  51     platforms = platforms.linux;
  52     maintainers = with maintainers; [ ];
  53     mainProgram = "anime";
  54   };
  55 }