pkgs/applications/video/mpv/scripts/mpv.nix

   1 { lib
   2 , buildLua
   3 , mpv-unwrapped
   4 }:
   5
   6 let mkBuiltin = name: args:
   7   let srcPath = "TOOLS/lua/${name}.lua";
   8   in buildLua (lib.attrsets.recursiveUpdate rec {
   9     inherit (mpv-unwrapped) src version;
  10     pname = "mpv-${name}";
  11
  12     dontUnpack = true;
  13     scriptPath = "${src}/${srcPath}";
  14
  15     meta = with lib; {
  16       inherit (mpv-unwrapped.meta) license;
  17       homepage = "https://github.com/mpv-player/mpv/blob/v${version}/${srcPath}";
  18     };
  19   } args);
  20
  21 in lib.mapAttrs (name: lib.makeOverridable (mkBuiltin name)) {
  22   acompressor.meta = {
  23     description = "Script to toggle and control ffmpeg's dynamic range compression filter.";
  24     maintainers = with lib.maintainers; [ nicoo ];
  25   };
  26
  27   autocrop.meta.description = "This script uses the lavfi cropdetect filter to automatically insert a crop filter with appropriate parameters for the currently playing video.";
  28
  29   autodeint.meta.description = "This script uses the lavfi idet filter to automatically insert the appropriate deinterlacing filter based on a short section of the currently playing video.";
  30
  31   autoload.meta = {
  32     description = "This script automatically loads playlist entries before and after the currently played file";
  33     maintainers = [ lib.maintainers.dawidsowa ];
  34   };
  35 }