pkgs/applications/video/xplayer/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , autoreconfHook
   5 , autoconf-archive
   6 , clutter-gst
   7 , clutter-gtk
   8 , gettext
   9 , glib
  10 , gobject-introspection
  11 , gst-plugins-bad
  12 , gst-plugins-base
  13 , gst-plugins-good
  14 , gstreamer
  15 , gtk-doc
  16 , gtk3
  17 , intltool
  18 , itstool
  19 , libpeas
  20 , libxml2
  21 , libxplayer-plparser
  22 , pkg-config
  23 , python3
  24 , wrapGAppsHook
  25 , xapp
  26 , yelp-tools }:
  27
  28 stdenv.mkDerivation rec {
  29   pname = "xplayer";
  30   version = "2.4.4";
  31
  32   src = fetchFromGitHub {
  33     owner = "linuxmint";
  34     repo = pname;
  35     rev = version;
  36     sha256 = "sha256-o2vLNIELd1EYWG26t5gOpnamJrBJeg4P6fcLirkcmfM=";
  37   };
  38
  39   # configure wants to find gst-inspect-1.0 via pkgconfig but
  40   # the gstreamer toolsdir points to the wrong derivation output
  41   postPatch = ''
  42     substituteInPlace configure.ac \
  43                       --replace '$gst10_toolsdir/gst-inspect-1.0' '${gstreamer}/bin/gst-inspect-1.0' \
  44   '';
  45
  46   preBuild = ''
  47     makeFlagsArray+=(
  48       "INCLUDES=-I${glib.dev}/include/gio-unix-2.0"
  49       "CFLAGS=-Wno-error" # Otherwise a lot of deprecated warnings are treated as error
  50     )
  51   '';
  52
  53   nativeBuildInputs = [
  54     autoreconfHook
  55     wrapGAppsHook
  56     autoconf-archive
  57     gettext
  58     gtk-doc
  59     intltool
  60     itstool
  61     pkg-config
  62     python3.pkgs.wrapPython
  63     yelp-tools
  64     gobject-introspection
  65   ];
  66
  67   buildInputs = [
  68     clutter-gst
  69     clutter-gtk
  70     glib
  71     gst-plugins-bad
  72     gst-plugins-base
  73     gst-plugins-good
  74     gstreamer
  75     gtk3
  76     libpeas
  77     libxml2
  78     libxplayer-plparser
  79     python3
  80     xapp
  81     # to satisfy configure script
  82     python3.pkgs.pygobject3
  83   ];
  84
  85   postFixup = ''
  86     buildPythonPath ${python3.pkgs.dbus-python}
  87     patchPythonScript $out/lib/xplayer/plugins/dbus/dbusservice.py
  88   '';
  89
  90   meta = with lib; {
  91     description = "A generic media player from Linux Mint";
  92     license = with licenses; [ gpl2Plus lgpl21Plus ];
  93     homepage = "https://github.com/linuxmint/xplayer";
  94     maintainers = with maintainers; [ tu-maurice bobby285271 ];
  95     platforms = platforms.linux;
  96   };
  97 }