pkgs/applications/virtualization/vpcs/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , testers
   5 , vpcs
   6 }:
   7
   8 stdenv.mkDerivation (finalAttrs: {
   9   pname = "vpcs";
  10   version = "0.8.3";
  11
  12   src = fetchFromGitHub {
  13     owner = "GNS3";
  14     repo = "vpcs";
  15     rev = "v${finalAttrs.version}";
  16     hash = "sha256-OKi4sC4fmKtkJkkpHZ6OfeIDaBafVrJXGXh1R6gLPFY=";
  17   };
  18
  19   sourceRoot = "${finalAttrs.src.name}/src";
  20
  21   buildPhase = ''
  22     runHook preBuild
  23
  24     MKOPT="CC=${stdenv.cc.targetPrefix}cc" ./mk.sh ${stdenv.buildPlatform.linuxArch}
  25
  26     runHook postBuild
  27   '';
  28
  29   installPhase = ''
  30     runHook preInstall
  31
  32     install -D -m555 vpcs $out/bin/vpcs
  33     install -D -m444 ../man/vpcs.1 $out/share/man/man1/vpcs.1
  34
  35     runHook postInstall
  36   '';
  37
  38   enableParallelBuilding = true;
  39
  40   passthru = {
  41     tests.version = testers.testVersion {
  42       package = vpcs;
  43       command = "vpcs -v";
  44     };
  45   };
  46
  47   meta = with lib; {
  48     description = "A simple virtual PC simulator";
  49     longDescription = ''
  50       The VPCS (Virtual PC Simulator) can simulate up to 9 PCs. You can
  51       ping/traceroute them, or ping/traceroute the other hosts/routers from the
  52       VPCS when you study the Cisco routers in the dynamips.
  53     '';
  54     inherit (finalAttrs.src.meta) homepage;
  55     license = licenses.bsd2;
  56     platforms = platforms.linux ++ platforms.darwin;
  57     mainProgram = "vpcs";
  58     maintainers = with maintainers; [ anthonyroussel ];
  59   };
  60 })