pkgs/development/tools/build-managers/sbt/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , jre
   5 , autoPatchelfHook
   6 , zlib
   7 }:
   8
   9 stdenv.mkDerivation (finalAttrs: {
  10   pname = "sbt";
  11   version = "1.9.9";
  12
  13   src = fetchurl {
  14     url = "https://github.com/sbt/sbt/releases/download/v${finalAttrs.version}/sbt-${finalAttrs.version}.tgz";
  15     hash = "sha256-xXyuYMISLKG7p3GE37TQ0l/GwYgFOUqzarYgiwwPJi8=";
  16   };
  17
  18   postPatch = ''
  19     echo -java-home ${jre.home} >>conf/sbtopts
  20   '';
  21
  22   nativeBuildInputs = lib.optionals stdenv.isLinux [ autoPatchelfHook ];
  23
  24   buildInputs = lib.optionals stdenv.isLinux [
  25     stdenv.cc.cc # libstdc++.so.6
  26     zlib
  27   ];
  28
  29   installPhase = ''
  30     runHook preInstall
  31
  32     mkdir -p $out/share/sbt $out/bin
  33     cp -ra . $out/share/sbt
  34     ln -sT ../share/sbt/bin/sbt $out/bin/sbt
  35     ln -sT ../share/sbt/bin/sbtn-${
  36       if (stdenv.hostPlatform.isAarch64) then "aarch64" else "x86_64"
  37     }-${
  38       if (stdenv.isDarwin) then "apple-darwin" else "pc-linux"
  39     } $out/bin/sbtn
  40
  41     runHook postInstall
  42   '';
  43
  44   meta = with lib; {
  45     homepage = "https://www.scala-sbt.org/";
  46     license = licenses.bsd3;
  47     sourceProvenance = with sourceTypes; [
  48       binaryBytecode
  49       binaryNativeCode
  50     ];
  51     description = "A build tool for Scala, Java and more";
  52     maintainers = with maintainers; [ nequissimus kashw2 ];
  53     platforms = platforms.unix;
  54   };
  55 })