pkgs/development/tools/build-managers/scons/4.5.2.nix

   1 { lib, fetchFromGitHub, python3 }:
   2
   3 let
   4   pname = "scons";
   5   version = "4.5.2";
   6   src = fetchFromGitHub {
   7     owner = "Scons";
   8     repo = "scons";
   9     rev = version;
  10     hash = "sha256-vxJsz24jDsPcttwPXq9+ztc/N7W4Gkydgykk/FLgZLo=";
  11   };
  12 in
  13 python3.pkgs.buildPythonApplication {
  14   inherit pname version src;
  15
  16   outputs = [ "out" "man" ];
  17
  18   patches = [
  19     ./env.patch
  20   ];
  21
  22   postPatch = ''
  23     substituteInPlace setup.cfg \
  24       --replace "build/dist" "dist" \
  25       --replace "build/doc/man/" ""
  26   '';
  27
  28   preConfigure = ''
  29     python scripts/scons.py
  30   '';
  31
  32   postInstall = ''
  33     mkdir -p "$man/share/man/man1"
  34     mv "$out/"*.1 "$man/share/man/man1/"
  35   '';
  36
  37   setupHook = ./setup-hook.sh;
  38
  39   # The release tarballs don't contain any tests (runtest.py and test/*):
  40   doCheck = false;
  41
  42   passthru = {
  43     # expose the used python version so tools using this (and extensing scos
  44     # with other python modules) can use the exact same python version.
  45     inherit python3;
  46     python = python3;
  47   };
  48
  49   meta = {
  50     description = "An improved, cross-platform substitute for Make";
  51     longDescription = ''
  52       SCons is an Open Source software construction tool. Think of SCons as an
  53       improved, cross-platform substitute for the classic Make utility with
  54       integrated functionality similar to autoconf/automake and compiler caches
  55       such as ccache. In short, SCons is an easier, more reliable and faster way
  56       to build software.
  57     '';
  58     homepage = "https://scons.org/";
  59     license = lib.licenses.mit;
  60     maintainers = with lib.maintainers; [ AndersonTorres ];
  61   };
  62 }