pkgs/development/tools/haskell/mueval/default.nix

   1 { lib, stdenv, makeWrapper, haskellPackages, packages ? (pkgs: [])
   2 }:
   3
   4 let defaultPkgs = pkgs: [ pkgs.show
   5                           pkgs.simple-reflect
   6                           pkgs.QuickCheck
   7                           pkgs.mtl
   8                         ];
   9     env = haskellPackages.ghcWithPackages
  10            (pkgs: defaultPkgs pkgs ++ packages pkgs);
  11
  12 in stdenv.mkDerivation {
  13   name = "mueval-env";
  14
  15   inherit (haskellPackages) mueval;
  16
  17   nativeBuildInputs = [ makeWrapper ];
  18
  19   dontUnpack = true;
  20
  21   buildPhase = ''
  22     runHook preBuild
  23
  24     mkdir -p $out/bin
  25
  26     makeWrapper $mueval/bin/mueval $out/bin/mueval \
  27       --set "NIX_GHC_LIBDIR" "$(${lib.getExe' env "ghc"} --print-libdir)"
  28
  29     runHook postBuild
  30   '';
  31
  32   doCheck = true;
  33
  34   checkPhase = ''
  35     [[ $($out/bin/mueval -e 42) == 42 ]]
  36   '';
  37
  38   passthru = { inherit defaultPkgs; };
  39   meta.mainProgram = "mueval";
  40 }