pkgs/development/tools/vagrant/default.nix

   1 { stdenv, lib, fetchurl, buildRubyGem, bundlerEnv, ruby, libarchive
   2 , libguestfs, qemu, writeText, withLibvirt ? stdenv.isLinux
   3 , openssl
   4 }:
   5
   6 let
   7   # NOTE: bumping the version and updating the hash is insufficient;
   8   # you must use bundix to generate a new gemset.nix in the Vagrant source.
   9   version = "2.4.1";
  10   url = "https://github.com/hashicorp/vagrant/archive/v${version}.tar.gz";
  11   hash = "sha256-Gc+jBuP/rl3b8wUE9hoaMSSqmodyGxMKFAmNTqH+v4k=";
  12
  13   deps = bundlerEnv rec {
  14     name = "${pname}-${version}";
  15     pname = "vagrant";
  16     inherit version;
  17
  18     inherit ruby;
  19     gemfile = writeText "Gemfile" "";
  20     lockfile = writeText "Gemfile.lock" "";
  21     gemset = lib.recursiveUpdate (import ./gemset.nix) ({
  22       vagrant = {
  23         source = {
  24           type = "url";
  25           inherit url hash;
  26         };
  27         inherit version;
  28       };
  29     } // lib.optionalAttrs withLibvirt (import ./gemset_libvirt.nix));
  30
  31     # This replaces the gem symlinks with directories, resolving this
  32     # error when running vagrant (I have no idea why):
  33     # /nix/store/p4hrycs0zaa9x0gsqylbk577ppnryixr-vagrant-2.2.6/lib/ruby/gems/2.6.0/gems/i18n-1.1.1/lib/i18n/config.rb:6:in `<module:I18n>': uninitialized constant I18n::Config (NameError)
  34     postBuild = ''
  35       for gem in "$out"/lib/ruby/gems/*/gems/*; do
  36         cp -a "$gem/" "$gem.new"
  37         rm "$gem"
  38         # needed on macOS, otherwise the mv yields permission denied
  39         chmod +w "$gem.new"
  40         mv "$gem.new" "$gem"
  41       done
  42     '';
  43   };
  44
  45 in buildRubyGem rec {
  46   name = "${gemName}-${version}";
  47   gemName = "vagrant";
  48   inherit version;
  49
  50   doInstallCheck = true;
  51   dontBuild = false;
  52   src = fetchurl { inherit url hash; };
  53
  54   # Some reports indicate that some connection types, particularly
  55   # WinRM, suffer from "Digest initialization failed" errors. Adding
  56   # openssl as a build input resolves this runtime error.
  57   buildInputs = [ openssl ];
  58
  59   patches = [
  60     ./unofficial-installation-nowarn.patch
  61     ./use-system-bundler-version.patch
  62     ./0004-Support-system-installed-plugins.patch
  63     ./0001-Revert-Merge-pull-request-12225-from-chrisroberts-re.patch
  64   ];
  65
  66   postPatch = ''
  67     substituteInPlace lib/vagrant/plugin/manager.rb --subst-var-by \
  68       system_plugin_dir "$out/vagrant-plugins"
  69   '';
  70
  71   # PATH additions:
  72   #   - libarchive: Make `bsdtar` available for extracting downloaded boxes
  73   # withLibvirt only:
  74   #   - libguestfs: Make 'virt-sysprep' available for 'vagrant package'
  75   #   - qemu: Make 'qemu-img' available for 'vagrant package'
  76   postInstall =
  77     let
  78       pathAdditions = lib.makeSearchPath "bin"
  79         (map (x: lib.getBin x) ([
  80           libarchive
  81         ] ++ lib.optionals withLibvirt [
  82           libguestfs
  83           qemu
  84         ]));
  85     in ''
  86     wrapProgram "$out/bin/vagrant" \
  87       --set GEM_PATH "${deps}/lib/ruby/gems/${ruby.version.libDir}" \
  88       --prefix PATH ':' ${pathAdditions} \
  89       --set-default VAGRANT_CHECKPOINT_DISABLE 1
  90
  91     mkdir -p "$out/vagrant-plugins/plugins.d"
  92     echo '{}' > "$out/vagrant-plugins/plugins.json"
  93
  94     # install bash completion
  95     mkdir -p $out/share/bash-completion/completions/
  96     cp -av contrib/bash/completion.sh $out/share/bash-completion/completions/vagrant
  97     # install zsh completion
  98     mkdir -p $out/share/zsh/site-functions/
  99     cp -av contrib/zsh/_vagrant $out/share/zsh/site-functions/
 100   '' +
 101   lib.optionalString withLibvirt ''
 102     substitute ${./vagrant-libvirt.json.in} $out/vagrant-plugins/plugins.d/vagrant-libvirt.json \
 103       --subst-var-by ruby_version ${ruby.version} \
 104       --subst-var-by vagrant_version ${version}
 105   '';
 106
 107   installCheckPhase = ''
 108     HOME="$(mktemp -d)" $out/bin/vagrant init --output - > /dev/null
 109   '';
 110
 111   passthru = {
 112     inherit ruby deps;
 113   };
 114
 115   meta = with lib; {
 116     description = "A tool for building complete development environments";
 117     homepage = "https://www.vagrantup.com/";
 118     license = licenses.bsl11;
 119     maintainers = with maintainers; [ tylerjl ];
 120     platforms = with platforms; linux ++ darwin;
 121   };
 122 }