pkgs/servers/etcd/3.5/default.nix

   1 { lib, buildGoModule, fetchFromGitHub, symlinkJoin, nixosTests, k3s }:
   2
   3 let
   4   version = "3.5.13";
   5   etcdSrcHash = "sha256-6dQXgM6VEWwv5CfHvxxPxdhMwNjFsinwhsbSqvQoDxI=";
   6   etcdServerVendorHash = "sha256-PB4gACfeYhdOXYs0xbcq2CmSMJnf/ifX2U2DN6zfJ1o=";
   7   etcdUtlVendorHash = "sha256-f23mn4zE6beM8yPSbs9gEEEifyF2D+CVKdlYwQtzAkQ=";
   8   etcdCtlVendorHash = "sha256-gSlyhmLKarDwc+MhYuTeTqwj0wLiN6+k2bHEVVTkyPc=";
   9
  10   src = fetchFromGitHub {
  11     owner = "etcd-io";
  12     repo = "etcd";
  13     rev = "v${version}";
  14     hash = etcdSrcHash;
  15   };
  16
  17   CGO_ENABLED = 0;
  18
  19   meta = with lib; {
  20     description = "Distributed reliable key-value store for the most critical data of a distributed system";
  21     license = licenses.asl20;
  22     homepage = "https://etcd.io/";
  23     maintainers = with maintainers; [ endocrimes offline superherointj ];
  24     platforms = platforms.darwin ++ platforms.linux;
  25   };
  26
  27   etcdserver = buildGoModule rec {
  28     pname = "etcdserver";
  29
  30     inherit CGO_ENABLED meta src version;
  31
  32     vendorHash = etcdServerVendorHash;
  33
  34     modRoot = "./server";
  35
  36     preInstall = ''
  37       mv $GOPATH/bin/{server,etcd}
  38     '';
  39
  40     # We set the GitSHA to `GitNotFound` to match official build scripts when
  41     # git is unavailable. This is to avoid doing a full Git Checkout of etcd.
  42     # User facing version numbers are still available in the binary, just not
  43     # the sha it was built from.
  44     ldflags = [ "-X go.etcd.io/etcd/api/v3/version.GitSHA=GitNotFound" ];
  45   };
  46
  47   etcdutl = buildGoModule rec {
  48     pname = "etcdutl";
  49
  50     inherit CGO_ENABLED meta src version;
  51
  52     vendorHash = etcdUtlVendorHash;
  53
  54     modRoot = "./etcdutl";
  55   };
  56
  57   etcdctl = buildGoModule rec {
  58     pname = "etcdctl";
  59
  60     inherit CGO_ENABLED meta src version;
  61
  62     vendorHash = etcdCtlVendorHash;
  63
  64     modRoot = "./etcdctl";
  65   };
  66 in
  67 symlinkJoin {
  68   name = "etcd-${version}";
  69
  70   inherit meta version;
  71
  72   passthru = {
  73     inherit etcdserver etcdutl etcdctl;
  74     tests = {
  75       inherit (nixosTests) etcd etcd-cluster;
  76       k3s = k3s.passthru.tests.etcd;
  77     };
  78     updateScript = ./update.sh;
  79   };
  80
  81   paths = [
  82     etcdserver
  83     etcdutl
  84     etcdctl
  85   ];
  86 }