pkgs/servers/http/tomcat/default.nix

   1 { stdenvNoCC, lib, fetchurl, nixosTests, testers, jre }:
   2
   3 let
   4   common = { version, hash }: stdenvNoCC.mkDerivation (finalAttrs: {
   5     pname = "apache-tomcat";
   6     inherit version;
   7
   8     src = fetchurl {
   9       url = "mirror://apache/tomcat/tomcat-${lib.versions.major version}/v${version}/bin/apache-tomcat-${version}.tar.gz";
  10       inherit hash;
  11     };
  12
  13     outputs = [ "out" "webapps" ];
  14     installPhase =
  15       ''
  16         mkdir $out
  17         mv * $out
  18         mkdir -p $webapps/webapps
  19         mv $out/webapps $webapps/
  20       '';
  21
  22     passthru.tests = {
  23       inherit (nixosTests) tomcat;
  24       version = testers.testVersion {
  25         package = finalAttrs.finalPackage;
  26         command = "JAVA_HOME=${jre} ${finalAttrs.finalPackage}/bin/version.sh";
  27       };
  28     };
  29
  30     meta = with lib; {
  31       homepage = "https://tomcat.apache.org/";
  32       description = "An implementation of the Java Servlet and JavaServer Pages technologies";
  33       platforms = jre.meta.platforms;
  34       maintainers = with maintainers; [ anthonyroussel ];
  35       license = [ licenses.asl20 ];
  36       sourceProvenance = with sourceTypes; [ binaryBytecode ];
  37     };
  38   });
  39
  40 in {
  41   tomcat9 = common {
  42     version = "9.0.87";
  43     hash = "sha256-2kgvuSIAhtvzceGAqgnGQCr48EhYZzTN7dSgjEjUzgI=";
  44   };
  45
  46   tomcat10 = common {
  47     version = "10.1.20";
  48     hash = "sha256-hCfFUJ8U5IKUCgFfP2DeIDQtPXLI3qmYKk1xEstxpu4=";
  49   };
  50 }