pkgs/servers/monitoring/loki/default.nix

   1 { stdenv
   2 , lib
   3 , buildGoModule
   4 , fetchFromGitHub
   5 , makeWrapper
   6 , nixosTests
   7 , systemd
   8 , testers
   9 , grafana-loki
  10 }:
  11
  12 buildGoModule rec {
  13   version = "3.0.0";
  14   pname = "grafana-loki";
  15
  16   src = fetchFromGitHub {
  17     owner = "grafana";
  18     repo = "loki";
  19     rev = "v${version}";
  20     hash = "sha256-2+OST6bKIjuhrXJKA+8vUERKT1/min7tN8oFxKn3L74=";
  21   };
  22
  23   vendorHash = null;
  24
  25   subPackages = [
  26     # TODO split every executable into its own package
  27     "cmd/loki"
  28     "cmd/loki-canary"
  29     "clients/cmd/promtail"
  30     "cmd/logcli"
  31   ];
  32
  33   tags = ["promtail_journal_enabled"];
  34
  35   nativeBuildInputs = [ makeWrapper ];
  36   buildInputs = lib.optionals stdenv.isLinux [ systemd.dev ];
  37
  38   preFixup = lib.optionalString stdenv.isLinux ''
  39     wrapProgram $out/bin/promtail \
  40       --prefix LD_LIBRARY_PATH : "${lib.getLib systemd}/lib"
  41   '';
  42
  43   passthru.tests = {
  44     inherit (nixosTests) loki;
  45     version = testers.testVersion {
  46       command = "loki --version";
  47       package = grafana-loki;
  48     };
  49   };
  50
  51   ldflags = let t = "github.com/grafana/loki/v3/pkg/util/build"; in [
  52     "-s"
  53     "-w"
  54     "-X ${t}.Version=${version}"
  55     "-X ${t}.BuildUser=nix@nixpkgs"
  56     "-X ${t}.BuildDate=unknown"
  57     "-X ${t}.Branch=unknown"
  58     "-X ${t}.Revision=unknown"
  59   ];
  60
  61   meta = with lib; {
  62     description = "Like Prometheus, but for logs";
  63     mainProgram = "promtail";
  64     license = with licenses; [ agpl3Only asl20 ];
  65     homepage = "https://grafana.com/oss/loki/";
  66     changelog = "https://github.com/grafana/loki/releases/tag/v${version}";
  67     maintainers = with maintainers; [ willibutz globin mmahut emilylange ] ++ teams.helsinki-systems.members;
  68   };
  69 }