pkgs/servers/monitoring/nagios/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , perl
   5 , php
   6 , gd
   7 , libpng
   8 , openssl
   9 , zlib
  10 , unzip
  11 , nixosTests
  12 , nix-update-script
  13 }:
  14
  15 stdenv.mkDerivation rec {
  16   pname = "nagios";
  17   version = "4.5.1";
  18
  19   src = fetchFromGitHub {
  20     owner = "NagiosEnterprises";
  21     repo = "nagioscore";
  22     rev = "refs/tags/nagios-${version}";
  23     hash = "sha256-+U2k3w3Yr0qZjHwjRpKZVucB3a35PSZr1Sqa8k0ssq8=";
  24   };
  25
  26   patches = [ ./nagios.patch ];
  27   nativeBuildInputs = [ unzip ];
  28
  29   buildInputs = [
  30     php
  31     perl
  32     gd
  33     libpng
  34     openssl
  35     zlib
  36   ];
  37
  38   configureFlags = [
  39     "--localstatedir=/var/lib/nagios"
  40     "--with-ssl=${openssl.dev}"
  41     "--with-ssl-inc=${openssl.dev}/include"
  42     "--with-ssl-lib=${lib.getLib openssl}/lib"
  43   ];
  44
  45   buildFlags = [ "all" ];
  46
  47   # Do not create /var directories
  48   preInstall = ''
  49     substituteInPlace Makefile --replace '$(MAKE) install-basic' ""
  50   '';
  51   installTargets = "install install-config";
  52   postInstall = ''
  53     # don't make default files use hardcoded paths to commands
  54     sed -i 's@command_line *[^ ]*/\([^/]*\) @command_line \1 @'  $out/etc/objects/commands.cfg
  55     sed -i 's@/usr/bin/@@g' $out/etc/objects/commands.cfg
  56     sed -i 's@/bin/@@g' $out/etc/objects/commands.cfg
  57   '';
  58
  59   passthru = {
  60     tests = {
  61       inherit (nixosTests) nagios;
  62     };
  63     updateScript = nix-update-script {
  64       extraArgs = [ "--version-regex" "nagios-(.*)" ];
  65     };
  66   };
  67
  68   meta = {
  69     description = "A host, service and network monitoring program";
  70     homepage = "https://www.nagios.org/";
  71     changelog = "https://github.com/NagiosEnterprises/nagioscore/blob/nagios-${version}/Changelog";
  72     license = lib.licenses.gpl2;
  73     platforms = lib.platforms.linux;
  74     mainProgram = "nagios";
  75     maintainers = with lib.maintainers; [ immae thoughtpolice relrod anthonyroussel ];
  76   };
  77 }