pkgs/servers/monitoring/plugins/labs_consol_de.nix

   1 { lib, stdenv, fetchFromGitHub, fetchurl, autoreconfHook, makeWrapper
   2 , perlPackages, coreutils, gnused, gnugrep }:
   3
   4 let
   5   glplugin = fetchFromGitHub {
   6     owner = "lausser";
   7     repo   = "GLPlugin";
   8     rev    = "ef3107f01afe55fad5452e64ac5bbea00b18a8d5";
   9     sha256 = "047fwrycsl2vmpi4wl46fs6f8y191d6qc9ms5rvmrj1dm2r828ws";
  10   };
  11
  12   generic = { pname, version, sha256, description, buildInputs, ... }:
  13   stdenv.mkDerivation {
  14     inherit pname version;
  15
  16     src = fetchurl {
  17       url = "https://labs.consol.de/assets/downloads/nagios/${pname}-${version}.tar.gz";
  18       inherit sha256;
  19     };
  20
  21     buildInputs = [ perlPackages.perl ] ++ buildInputs;
  22
  23     nativeBuildInputs = [ autoreconfHook makeWrapper ];
  24
  25     prePatch = with lib; ''
  26       rm -rf GLPlugin
  27       ln -s ${glplugin} GLPlugin
  28       substituteInPlace plugins-scripts/Makefile.am \
  29         --replace /bin/cat  ${getBin coreutils}/bin/cat \
  30         --replace /bin/echo ${getBin coreutils}/bin/echo \
  31         --replace /bin/grep ${getBin gnugrep}/bin/grep \
  32         --replace /bin/sed  ${getBin gnused}/bin/sed
  33     '';
  34
  35     postInstall = ''
  36       test -d $out/libexec && ln -sr $out/libexec $out/bin
  37     '';
  38
  39     postFixup = ''
  40       for f in $out/bin/* ; do
  41         wrapProgram $f --prefix PERL5LIB : $PERL5LIB
  42       done
  43     '';
  44
  45     meta = with lib; {
  46       homepage    = "https://labs.consol.de/";
  47       license     = licenses.gpl2;
  48       maintainers = with maintainers; [ peterhoeg ];
  49       inherit description;
  50     };
  51   };
  52
  53 in {
  54   check-mssql-health = generic {
  55     pname       = "check_mssql_health";
  56     version     = "2.6.4.15";
  57     sha256      = "12z0b3c2p18viy7s93r6bbl8fvgsqh80136d07118qhxshp1pwxg";
  58     description = "Check plugin for Microsoft SQL Server";
  59     buildInputs = [ perlPackages.DBDsybase ];
  60   };
  61
  62   check-nwc-health = generic {
  63     pname       = "check_nwc_health";
  64     version     = "7.10.0.6";
  65     sha256      = "092rhaqnk3403z0y60x38vgh65gcia3wrd6gp8mr7wszja38kxv2";
  66     description = "Check plugin for network equipment";
  67     buildInputs = [ perlPackages.NetSNMP ];
  68   };
  69
  70   check-ups-health = generic {
  71     pname       = "check_ups_health";
  72     version     = "2.8.3.3";
  73     sha256      = "0qc2aglppwr9ms4p53kh9nr48625sqrbn46xs0k9rx5sv8hil9hm";
  74     description = "Check plugin for UPSs";
  75     buildInputs = [ perlPackages.NetSNMP ];
  76   };
  77 }