pkgs/servers/nosql/cassandra/generic.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , python
   5 , makeWrapper
   6 , gawk
   7 , bash
   8 , getopt
   9 , procps
  10 , which
  11 , jre
  12 , nixosTests
  13   # generation is the attribute version suffix such as 3_11 in pkgs.cassandra_3_11
  14 , generation
  15 , version
  16 , sha256
  17 , extraMeta ? { }
  18 , callPackage
  19 , ...
  20 }:
  21
  22 let
  23   libPath = lib.makeLibraryPath [ stdenv.cc.cc ];
  24   binPath = lib.makeBinPath [
  25     bash
  26     getopt
  27     gawk
  28     which
  29     jre
  30     procps
  31   ];
  32 in
  33
  34 stdenv.mkDerivation rec {
  35   pname = "cassandra";
  36   inherit version;
  37
  38   src = fetchurl {
  39     inherit sha256;
  40     url = "mirror://apache/cassandra/${version}/apache-cassandra-${version}-bin.tar.gz";
  41   };
  42
  43   nativeBuildInputs = [ makeWrapper ];
  44
  45   installPhase = ''
  46     runHook preInstall
  47
  48     mkdir $out
  49     mv * $out
  50
  51     # Clean up documentation.
  52     mkdir -p $out/share/doc/${pname}-${version}
  53     mv $out/CHANGES.txt \
  54        $out/LICENSE.txt \
  55        $out/NEWS.txt \
  56        $out/NOTICE.txt \
  57        $out/share/doc/${pname}-${version}
  58
  59     if [[ -d $out/doc ]]; then
  60       mv "$out/doc/"* $out/share/doc/${pname}-${version}
  61       rmdir $out/doc
  62     fi
  63
  64
  65     for cmd in bin/cassandra \
  66                bin/nodetool \
  67                bin/sstablekeys \
  68                bin/sstableloader \
  69                bin/sstablescrub \
  70                bin/sstableupgrade \
  71                bin/sstableutil \
  72                bin/sstableverify; do
  73       # Check if file exists because some don't exist across all versions
  74       if [ -f $out/$cmd ]; then
  75         wrapProgram $out/bin/$(basename "$cmd") \
  76           --suffix-each LD_LIBRARY_PATH : ${libPath} \
  77           --prefix PATH : ${binPath} \
  78           --set JAVA_HOME ${jre}
  79       fi
  80     done
  81
  82     for cmd in tools/bin/cassandra-stress \
  83                tools/bin/cassandra-stressd \
  84                tools/bin/sstabledump \
  85                tools/bin/sstableexpiredblockers \
  86                tools/bin/sstablelevelreset \
  87                tools/bin/sstablemetadata \
  88                tools/bin/sstableofflinerelevel \
  89                tools/bin/sstablerepairedset \
  90                tools/bin/sstablesplit \
  91                tools/bin/token-generator; do
  92       # Check if file exists because some don't exist across all versions
  93       if [ -f $out/$cmd ]; then
  94         makeWrapper $out/$cmd $out/bin/$(basename "$cmd") \
  95           --suffix-each LD_LIBRARY_PATH : ${libPath} \
  96           --prefix PATH : ${binPath} \
  97           --set JAVA_HOME ${jre}
  98       fi
  99     done
 100
 101     wrapProgram $out/bin/cqlsh --prefix PATH : ${python}/bin
 102
 103     runHook postInstall
 104   '';
 105
 106   passthru = {
 107     tests =
 108       let
 109         test = nixosTests."cassandra_${generation}";
 110       in
 111       {
 112         nixos =
 113           assert test.testPackage.version == version;
 114           test;
 115       };
 116
 117     updateScript = callPackage ./update-script.nix { inherit generation; };
 118   };
 119
 120   meta = with lib; {
 121     homepage = "https://cassandra.apache.org/";
 122     description = "A massively scalable open source NoSQL database";
 123     platforms = platforms.unix;
 124     license = licenses.asl20;
 125     maintainers = [ maintainers.roberth ];
 126   } // extraMeta;
 127 }