pkgs/servers/nosql/eventstore/default.nix

   1 { lib
   2 , git
   3 , dotnetCorePackages
   4 , glibcLocales
   5 , buildDotnetModule
   6 , fetchFromGitHub
   7 , bintools
   8 , stdenv
   9 , mono
  10 }:
  11 let
  12   mainProgram = "EventStore.ClusterNode";
  13 in
  14
  15 buildDotnetModule rec {
  16   pname = "EventStore";
  17   version = "23.6.0";
  18
  19   src = fetchFromGitHub {
  20     owner = "EventStore";
  21     repo = "EventStore";
  22     rev = "oss-v${version}";
  23     sha256 = "sha256-+Wxm6yusaCoqXIbsi0ZoALAviKUyNMQwbzsQtBK/PCo=";
  24     leaveDotGit = true;
  25   };
  26
  27   # Fixes application reporting 0.0.0.0 as its version.
  28   MINVERVERSIONOVERRIDE = version;
  29
  30   dotnet-sdk = dotnetCorePackages.sdk_6_0;
  31   dotnet-runtime = dotnetCorePackages.aspnetcore_6_0;
  32
  33   nativeBuildInputs = [ git glibcLocales bintools ];
  34
  35   runtimeDeps = [ mono ];
  36
  37   executables = [ mainProgram ];
  38
  39   # This test has a problem running on macOS
  40   disabledTests = lib.optionals stdenv.isDarwin [
  41     "EventStore.Projections.Core.Tests.Services.grpc_service.ServerFeaturesTests<LogFormat+V2,String>.should_receive_expected_endpoints"
  42     "EventStore.Projections.Core.Tests.Services.grpc_service.ServerFeaturesTests<LogFormat+V3,UInt32>.should_receive_expected_endpoints"
  43   ];
  44
  45   postConfigure = ''
  46     # Fixes git execution by GitInfo on mac os
  47     substituteInPlace "$HOME/.nuget/packages/gitinfo/2.0.26/build/GitInfo.targets" \
  48       --replace "<GitExe Condition=\"Exists('/usr/bin/git')\">/usr/bin/git</GitExe>" " " \
  49       --replace "<GitExe Condition=\"Exists('/usr/local/bin/git')\">/usr/local/bin/git</GitExe>" ""
  50   '';
  51
  52   nugetDeps = ./deps.nix;
  53
  54   projectFile = "src/EventStore.ClusterNode/EventStore.ClusterNode.csproj";
  55
  56   doCheck = true;
  57   testProjectFile = "src/EventStore.Projections.Core.Tests/EventStore.Projections.Core.Tests.csproj";
  58
  59   doInstallCheck = true;
  60   installCheckPhase = ''
  61     $out/bin/EventStore.ClusterNode --insecure \
  62       --db "$HOME/data" \
  63       --index "$HOME/index" \
  64       --log "$HOME/log" \
  65       -runprojections all --startstandardprojections \
  66       --EnableAtomPubOverHttp &
  67
  68     PID=$!
  69
  70     sleep 30s;
  71     kill "$PID";
  72   '';
  73
  74   passthru.updateScript = ./updater.sh;
  75
  76   meta = with lib; {
  77     homepage = "https://geteventstore.com/";
  78     description = "Event sourcing database with processing logic in JavaScript";
  79     license = licenses.bsd3;
  80     maintainers = with maintainers; [ puffnfresh mdarocha ];
  81     platforms = [ "x86_64-linux" "x86_64-darwin" ];
  82     inherit mainProgram;
  83   };
  84 }