pkgs/servers/polaris/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , rustPlatform
   5 , nix-update-script
   6 , polaris-web
   7 , darwin
   8 , nixosTests
   9 }:
  10
  11 rustPlatform.buildRustPackage rec {
  12   pname = "polaris";
  13   version = "0.14.2";
  14
  15   src = fetchFromGitHub {
  16     owner = "agersant";
  17     repo = "polaris";
  18     rev = version;
  19     hash = "sha256-UC66xRL9GyTPHJ3z0DD/yyI9GlyqelCaHHDyl79ptJg=";
  20
  21     # The polaris version upstream in Cargo.lock is "0.0.0".
  22     # We're unable to simply patch it in the patch phase due to
  23     # rustPlatform.buildRustPackage fetching dependencies before applying patches.
  24     # If we patch it after fetching dependencies we get an error when
  25     # validating consistency between the final build and the prefetched deps.
  26     postFetch = ''
  27       # 'substituteInPlace' does not support multiline replacements?
  28       sed -i $out/Cargo.lock -z \
  29         -e 's/\[\[package\]\]\nname = "polaris"\nversion = "0.0.0"/[[package]]\nname = "polaris"\nversion = "'"${version}"'"/g'
  30     '';
  31   };
  32
  33   cargoHash = "sha256-+4WN6TTIzVu3Jj0SfPq2jnYh0oWRo/C4qDMeJLrj1kk=";
  34
  35   buildInputs = lib.optionals stdenv.isDarwin [
  36     darwin.Security
  37   ];
  38
  39   # Compile-time environment variables for where to find assets needed at runtime
  40   env = {
  41     POLARIS_WEB_DIR = "${polaris-web}/share/polaris-web";
  42     POLARIS_SWAGGER_DIR = "${placeholder "out"}/share/polaris-swagger";
  43   };
  44
  45   postInstall = ''
  46     mkdir -p $out/share
  47     cp -a docs/swagger $out/share/polaris-swagger
  48   '';
  49
  50   preCheck = ''
  51     # 'Err' value: Os { code: 24, kind: Uncategorized, message: "Too many open files" }
  52     ulimit -n 4096
  53   '';
  54
  55   __darwinAllowLocalNetworking = true;
  56
  57   passthru.tests = nixosTests.polaris;
  58   passthru.updateScript = nix-update-script {
  59     attrPath = pname;
  60   };
  61
  62   meta = with lib; {
  63     description = "Self-host your music collection, and access it from any computer and mobile device";
  64     longDescription = ''
  65       Polaris is a FOSS music streaming application, designed to let you enjoy your music collection
  66       from any computer or mobile device. Polaris works by streaming your music directly from your
  67       own computer, without uploading it to a third-party. There are no  kind of premium version.
  68       The only requirement is that your computer stays on while it streams your music!
  69     '';
  70     homepage = "https://github.com/agersant/polaris";
  71     license = licenses.mit;
  72     maintainers = with maintainers; [ pbsds ];
  73     platforms = platforms.unix;
  74     mainProgram = "polaris";
  75   };
  76 }