pkgs/servers/redpanda/default.nix

   1 { buildGoModule
   2 , callPackage
   3 , doCheck ? !stdenv.isDarwin # Can't start localhost test server in MacOS sandbox.
   4 , fetchFromGitHub
   5 , installShellFiles
   6 , lib
   7 , stdenv
   8 }:
   9 let
  10   version = "23.3.12";
  11   src = fetchFromGitHub {
  12     owner = "redpanda-data";
  13     repo = "redpanda";
  14     rev = "v${version}";
  15     sha256 = "sha256-gkJlqyPDsWaXcbOGB7m70YuHY44xLNymf9laK30yr1k=";
  16   };
  17   server = callPackage ./server.nix { inherit src version; };
  18 in
  19 buildGoModule rec {
  20   pname = "redpanda-rpk";
  21   inherit doCheck src version;
  22   modRoot = "./src/go/rpk";
  23   runVend = false;
  24   vendorHash = "sha256-B//qmqxS3g9u2yir8Z3iV2fjQ4XXPAjFujeOZjdt8PE=";
  25
  26   ldflags = [
  27     ''-X "github.com/redpanda-data/redpanda/src/go/rpk/pkg/cli/cmd/version.version=${version}"''
  28     ''-X "github.com/redpanda-data/redpanda/src/go/rpk/pkg/cli/cmd/version.rev=v${version}"''
  29     ''-X "github.com/redpanda-data/redpanda/src/go/rpk/pkg/cli/cmd/container/common.tag=v${version}"''
  30   ];
  31
  32   nativeBuildInputs = [ installShellFiles ];
  33
  34   postInstall = ''
  35     for shell in bash fish zsh; do
  36       $out/bin/rpk generate shell-completion $shell > rpk.$shell
  37       installShellCompletion rpk.$shell
  38     done
  39   '';
  40
  41   passthru = {
  42     inherit server;
  43   };
  44
  45   meta = with lib; {
  46     description = "Redpanda client";
  47     homepage = "https://redpanda.com/";
  48     license = licenses.bsl11;
  49     maintainers = with maintainers; [ avakhrenev happysalada ];
  50     platforms = platforms.all;
  51     mainProgram = "rpk";
  52   };
  53 }