pkgs/servers/search/groonga/default.nix

   1 { lib, stdenv, cmake, fetchurl, kytea, msgpack-c, mecab, pkg-config, rapidjson, testers, xxHash, zstd, postgresqlPackages
   2 , suggestSupport ? false, zeromq, libevent, openssl
   3 , lz4Support  ? false, lz4
   4 , zlibSupport ? true, zlib
   5 }:
   6
   7 stdenv.mkDerivation (finalAttrs: {
   8   pname = "groonga";
   9   version = "14.0.2";
  10
  11   src = fetchurl {
  12     url = "https://packages.groonga.org/source/groonga/groonga-${finalAttrs.version}.tar.gz";
  13     hash = "sha256-o9C6lPOPkb2KCbF4CqLyKtXHfOdB3jAIv5P6SjTJAJc=";
  14   };
  15
  16   patches = [
  17     ./fix-cmake-install-path.patch
  18     ./do-not-use-vendored-libraries.patch
  19   ];
  20
  21   nativeBuildInputs = [
  22     cmake
  23     pkg-config
  24   ];
  25
  26   buildInputs = [
  27     rapidjson
  28     xxHash
  29     zstd
  30     mecab
  31     kytea
  32     msgpack-c
  33   ] ++ lib.optionals lz4Support [
  34     lz4
  35   ] ++ lib.optional zlibSupport [
  36     zlib
  37   ] ++ lib.optionals suggestSupport [
  38     zeromq
  39     libevent
  40   ];
  41
  42   env.NIX_CFLAGS_COMPILE = lib.optionalString zlibSupport "-I${zlib.dev}/include";
  43
  44   passthru.tests = {
  45     inherit (postgresqlPackages) pgroonga;
  46     version = testers.testVersion {
  47       package = finalAttrs.finalPackage;
  48     };
  49     pkg-config = testers.hasPkgConfigModules {
  50       package = finalAttrs.finalPackage;
  51       moduleNames = [ "groonga" ];
  52     };
  53   };
  54
  55   meta = with lib; {
  56     homepage = "https://groonga.org/";
  57     description = "An open-source fulltext search engine and column store";
  58     license = licenses.lgpl21;
  59     maintainers = [ maintainers.ericsagnes ];
  60     platforms = platforms.all;
  61     longDescription = ''
  62       Groonga is an open-source fulltext search engine and column store.
  63       It lets you write high-performance applications that requires fulltext search.
  64     '';
  65   };
  66 })