pkgs/servers/x11/xorg/xwayland.nix

   1 { egl-wayland
   2 , libepoxy
   3 , fetchurl
   4 , fontutil
   5 , lib
   6 , libei
   7 , libGL
   8 , libGLU
   9 , libX11
  10 , libXau
  11 , libXaw
  12 , libXdmcp
  13 , libXext
  14 , libXfixes
  15 , libXfont2
  16 , libXmu
  17 , libXpm
  18 , libXrender
  19 , libXres
  20 , libXt
  21 , libdrm
  22 , libtirpc
  23 , withLibunwind ? true, libunwind
  24 , libxcb
  25 , libxkbfile
  26 , libxshmfence
  27 , libxcvt
  28 , mesa
  29 , meson
  30 , ninja
  31 , openssl
  32 , pkg-config
  33 , pixman
  34 , stdenv
  35 , wayland
  36 , wayland-protocols
  37 , wayland-scanner
  38 , xkbcomp
  39 , xkeyboard_config
  40 , xorgproto
  41 , xtrans
  42 , zlib
  43 , defaultFontPath ? ""
  44 , gitUpdater
  45 }:
  46
  47 stdenv.mkDerivation rec {
  48   pname = "xwayland";
  49   version = "23.2.6";
  50
  51   src = fetchurl {
  52     url = "mirror://xorg/individual/xserver/${pname}-${version}.tar.xz";
  53     hash = "sha256-HJo2a058ytug+b0xPFnq4S0jvXJUOyKibq+LIINc/G0=";
  54   };
  55
  56   depsBuildBuild = [
  57     pkg-config
  58   ];
  59   nativeBuildInputs = [
  60     pkg-config
  61     meson
  62     ninja
  63     wayland-scanner
  64   ];
  65   buildInputs = [
  66     egl-wayland
  67     libepoxy
  68     libei
  69     fontutil
  70     libGL
  71     libGLU
  72     libX11
  73     libXau
  74     libXaw
  75     libXdmcp
  76     libXext
  77     libXfixes
  78     libXfont2
  79     libXmu
  80     libXpm
  81     libXrender
  82     libXres
  83     libXt
  84     libdrm
  85     libtirpc
  86     libxcb
  87     libxkbfile
  88     libxshmfence
  89     libxcvt
  90     mesa
  91     openssl
  92     pixman
  93     wayland
  94     wayland-protocols
  95     xkbcomp
  96     xorgproto
  97     xtrans
  98     zlib
  99   ] ++ lib.optionals withLibunwind [
 100     libunwind
 101   ];
 102   mesonFlags = [
 103     (lib.mesonBool "xwayland_eglstream" true)
 104     (lib.mesonBool "xcsecurity" true)
 105     (lib.mesonOption "default_font_path" defaultFontPath)
 106     (lib.mesonOption "xkb_bin_dir" "${xkbcomp}/bin")
 107     (lib.mesonOption "xkb_dir" "${xkeyboard_config}/etc/X11/xkb")
 108     (lib.mesonOption "xkb_output_dir" "${placeholder "out"}/share/X11/xkb/compiled")
 109     (lib.mesonBool "libunwind" withLibunwind)
 110   ];
 111
 112   passthru.updateScript = gitUpdater {
 113     # No nicer place to find latest release.
 114     url = "https://gitlab.freedesktop.org/xorg/xserver.git";
 115     rev-prefix = "xwayland-";
 116   };
 117
 118   meta = with lib; {
 119     description = "An X server for interfacing X11 apps with the Wayland protocol";
 120     homepage = "https://wayland.freedesktop.org/xserver.html";
 121     license = licenses.mit;
 122     mainProgram = "Xwayland";
 123     maintainers = with maintainers; [ emantor ];
 124     platforms = platforms.linux;
 125   };
 126 }