pkgs/servers/xmpp/prosody/default.nix

   1 { stdenv, fetchurl, lib, libidn, openssl, makeWrapper, fetchhg, buildPackages
   2 , icu
   3 , lua
   4 , nixosTests
   5 , withDBI ? true
   6 # use withExtraLibs to add additional dependencies of community modules
   7 , withExtraLibs ? [ ]
   8 , withExtraLuaPackages ? _: [ ]
   9 , withOnlyInstalledCommunityModules ? [ ]
  10 , withCommunityModules ? [ ] }:
  11
  12 with lib;
  13
  14 let
  15   luaEnv = lua.withPackages(p: with p; [
  16       luasocket luasec luaexpat luafilesystem luabitop luadbi-sqlite3 luaunbound
  17     ]
  18     ++ lib.optional withDBI p.luadbi
  19     ++ withExtraLuaPackages p
  20   );
  21 in
  22 stdenv.mkDerivation rec {
  23   version = "0.12.4"; # also update communityModules
  24   pname = "prosody";
  25   # The following community modules are necessary for the nixos module
  26   # prosody module to comply with XEP-0423 and provide a working
  27   # default setup.
  28   nixosModuleDeps = [
  29     "cloud_notify"
  30     "vcard_muc"
  31     "http_upload"
  32   ];
  33   src = fetchurl {
  34     url = "https://prosody.im/downloads/source/${pname}-${version}.tar.gz";
  35     sha256 = "R9cSJzwvKVWMQS9s2uwHMmC7wmt92iQ9tYAzAYPWWFY=";
  36   };
  37
  38   # A note to all those merging automated updates: Please also update this
  39   # attribute as some modules might not be compatible with a newer prosody
  40   # version.
  41   communityModules = fetchhg {
  42     url = "https://hg.prosody.im/prosody-modules";
  43     rev = "b109773ce6fe";
  44     hash = "sha256-N1vmShDWtWsHD4b1x7UjX6Sj28iPaDeCLSYeDOLLhzo=";
  45   };
  46
  47   nativeBuildInputs = [ makeWrapper ];
  48   buildInputs = [
  49     luaEnv libidn openssl icu
  50   ]
  51   ++ withExtraLibs;
  52
  53   configureFlags = [
  54     "--ostype=linux"
  55     "--with-lua-bin=${lib.getBin buildPackages.lua}/bin"
  56     "--with-lua-include=${luaEnv}/include"
  57     "--with-lua=${luaEnv}"
  58     "--c-compiler=${stdenv.cc.targetPrefix}cc"
  59     "--linker=${stdenv.cc.targetPrefix}cc"
  60   ];
  61   configurePlatforms = [];
  62
  63   postBuild = ''
  64     make -C tools/migration
  65   '';
  66
  67   # the wrapping should go away once lua hook is fixed
  68   postInstall = ''
  69       ${concatMapStringsSep "\n" (module: ''
  70         cp -r $communityModules/mod_${module} $out/lib/prosody/modules/
  71       '') (lib.lists.unique(nixosModuleDeps ++ withCommunityModules ++ withOnlyInstalledCommunityModules))}
  72       wrapProgram $out/bin/prosodyctl \
  73         --add-flags '--config "/etc/prosody/prosody.cfg.lua"'
  74       make -C tools/migration install
  75     '';
  76
  77   passthru = {
  78     communityModules = withCommunityModules;
  79     tests = { inherit (nixosTests) prosody prosody-mysql; };
  80   };
  81
  82   meta = {
  83     description = "Open-source XMPP application server written in Lua";
  84     license = licenses.mit;
  85     homepage = "https://prosody.im";
  86     platforms = platforms.linux;
  87     maintainers = with maintainers; [ toastal ];
  88   };
  89 }