flake.nix

   1 # Experimental flake interface to Nixpkgs.
   2 # See https://github.com/NixOS/rfcs/pull/49 for details.
   3 {
   4   description = "A collection of packages for the Nix package manager";
   5
   6   outputs = { self }:
   7     let
   8       jobs = import ./pkgs/top-level/release.nix {
   9         nixpkgs = self;
  10       };
  11
  12       lib = import ./lib;
  13
  14       forAllSystems = f: lib.genAttrs lib.systems.flakeExposed (system: f system);
  15
  16     in
  17     {
  18       lib = lib.extend (final: prev: {
  19
  20         nixos = import ./nixos/lib { lib = final; };
  21
  22         nixosSystem = args:
  23           import ./nixos/lib/eval-config.nix (args // {
  24             modules = args.modules ++ [ {
  25               system.nixos.versionSuffix =
  26                 ".${final.substring 0 8 (self.lastModifiedDate or self.lastModified or "19700101")}.${self.shortRev or "dirty"}";
  27               system.nixos.revision = final.mkIf (self ? rev) self.rev;
  28             } ];
  29           });
  30       });
  31
  32       checks.x86_64-linux.tarball = jobs.tarball;
  33
  34       htmlDocs = {
  35         nixpkgsManual = jobs.manual;
  36         nixosManual = (import ./nixos/release-small.nix {
  37           nixpkgs = self;
  38         }).nixos.manual.x86_64-linux;
  39       };
  40
  41       legacyPackages = forAllSystems (system: import ./. { inherit system; });
  42
  43       nixosModules = {
  44         notDetected = import ./nixos/modules/installer/scan/not-detected.nix;
  45       };
  46     };
  47 }