doc/languages-frameworks/perl.section.md

   1 # Perl {#sec-language-perl}
   2
   3 ## Running Perl programs on the shell {#ssec-perl-running}
   4
   5 When executing a Perl script, it is possible you get an error such as `./myscript.pl: bad interpreter: /usr/bin/perl: no such file or directory`. This happens when the script expects Perl to be installed at `/usr/bin/perl`, which is not the case when using Perl from nixpkgs. You can fix the script by changing the first line to:
   6
   7 ```perl
   8 #!/usr/bin/env perl
   9 ```
  10
  11 to take the Perl installation from the `PATH` environment variable, or invoke Perl directly with:
  12
  13 ```ShellSession
  14 $ perl ./myscript.pl
  15 ```
  16
  17 When the script is using a Perl library that is not installed globally, you might get an error such as `Can't locate DB_File.pm in @INC (you may need to install the DB_File module)`. In that case, you can use `nix-shell` to start an ad-hoc shell with that library installed, for instance:
  18
  19 ```ShellSession
  20 $ nix-shell -p perl perlPackages.DBFile --run ./myscript.pl
  21 ```
  22
  23 If you are always using the script in places where `nix-shell` is available, you can embed the `nix-shell` invocation in the shebang like this:
  24
  25 ```perl
  26 #!/usr/bin/env nix-shell
  27 #! nix-shell -i perl -p perl perlPackages.DBFile
  28 ```
  29
  30 ## Packaging Perl programs {#ssec-perl-packaging}
  31
  32 Nixpkgs provides a function `buildPerlPackage`, a generic package builder function for any Perl package that has a standard `Makefile.PL`. It’s implemented in [pkgs/development/perl-modules/generic](https://github.com/NixOS/nixpkgs/blob/master/pkgs/development/perl-modules/generic).
  33
  34 Perl packages from CPAN are defined in [pkgs/top-level/perl-packages.nix](https://github.com/NixOS/nixpkgs/blob/master/pkgs/top-level/perl-packages.nix) rather than `pkgs/all-packages.nix`. Most Perl packages are so straight-forward to build that they are defined here directly, rather than having a separate function for each package called from `perl-packages.nix`. However, more complicated packages should be put in a separate file, typically in `pkgs/development/perl-modules`. Here is an example of the former:
  35
  36 ```nix
  37 ClassC3 = buildPerlPackage rec {
  38   pname = "Class-C3";
  39   version = "0.21";
  40   src = fetchurl {
  41     url = "mirror://cpan/authors/id/F/FL/FLORA/${pname}-${version}.tar.gz";
  42     hash = "sha256-/5GE5xHT0uYGOQxroqj6LMU7CtKn2s6vMVoSXxL4iK4=";
  43   };
  44 };
  45 ```
  46
  47 Note the use of `mirror://cpan/`, and the `pname` and `version` in the URL definition to ensure that the `pname` attribute is consistent with the source that we’re actually downloading. Perl packages are made available in `all-packages.nix` through the variable `perlPackages`. For instance, if you have a package that needs `ClassC3`, you would typically write
  48
  49 ```nix
  50 foo = import ../path/to/foo.nix {
  51   inherit stdenv fetchurl ...;
  52   inherit (perlPackages) ClassC3;
  53 };
  54 ```
  55
  56 in `all-packages.nix`. You can test building a Perl package as follows:
  57
  58 ```ShellSession
  59 $ nix-build -A perlPackages.ClassC3
  60 ```
  61
  62 To install it with `nix-env` instead: `nix-env -f. -iA perlPackages.ClassC3`.
  63
  64 So what does `buildPerlPackage` do? It does the following:
  65
  66 1. In the configure phase, it calls `perl Makefile.PL` to generate a Makefile. You can set the variable `makeMakerFlags` to pass flags to `Makefile.PL`
  67 2. It adds the contents of the `PERL5LIB` environment variable to `#! .../bin/perl` line of Perl scripts as `-Idir` flags. This ensures that a script can find its dependencies. (This can cause this shebang line to become too long for Darwin to handle; see the note below.)
  68 3. In the fixup phase, it writes the propagated build inputs (`propagatedBuildInputs`) to the file `$out/nix-support/propagated-user-env-packages`. `nix-env` recursively installs all packages listed in this file when you install a package that has it. This ensures that a Perl package can find its dependencies.
  69
  70 `buildPerlPackage` is built on top of `stdenv`, so everything can be customised in the usual way. For instance, the `BerkeleyDB` module has a `preConfigure` hook to generate a configuration file used by `Makefile.PL`:
  71
  72 ```nix
  73 { buildPerlPackage, fetchurl, db }:
  74
  75 buildPerlPackage rec {
  76   pname = "BerkeleyDB";
  77   version = "0.36";
  78
  79   src = fetchurl {
  80     url = "mirror://cpan/authors/id/P/PM/PMQS/${pname}-${version}.tar.gz";
  81     hash = "sha256-4Y+HGgGQqcOfdiKcFIyMrWBEccVNVAMDBWZlFTMorh8=";
  82   };
  83
  84   preConfigure = ''
  85     echo "LIB = ${db.out}/lib" > config.in
  86     echo "INCLUDE = ${db.dev}/include" >> config.in
  87   '';
  88 }
  89 ```
  90
  91 Dependencies on other Perl packages can be specified in the `buildInputs` and `propagatedBuildInputs` attributes. If something is exclusively a build-time dependency, use `buildInputs`; if it’s (also) a runtime dependency, use `propagatedBuildInputs`. For instance, this builds a Perl module that has runtime dependencies on a bunch of other modules:
  92
  93 ```nix
  94 ClassC3Componentised = buildPerlPackage rec {
  95   pname = "Class-C3-Componentised";
  96   version = "1.0004";
  97   src = fetchurl {
  98     url = "mirror://cpan/authors/id/A/AS/ASH/${pname}-${version}.tar.gz";
  99     hash = "sha256-ASO9rV/FzJYZ0BH572Fxm2ZrFLMZLFATJng1NuU4FHc=";
 100   };
 101   propagatedBuildInputs = [
 102     ClassC3 ClassInspector TestException MROCompat
 103   ];
 104 };
 105 ```
 106
 107 On Darwin, if a script has too many `-Idir` flags in its first line (its “shebang line”), it will not run. This can be worked around by calling the `shortenPerlShebang` function from the `postInstall` phase:
 108
 109 ```nix
 110 { lib, stdenv, buildPerlPackage, fetchurl, shortenPerlShebang }:
 111
 112 ImageExifTool = buildPerlPackage {
 113   pname = "Image-ExifTool";
 114   version = "12.50";
 115
 116   src = fetchurl {
 117     url = "https://exiftool.org/${pname}-${version}.tar.gz";
 118     hash = "sha256-vOhB/FwQMC8PPvdnjDvxRpU6jAZcC6GMQfc0AH4uwKg=";
 119   };
 120
 121   nativeBuildInputs = lib.optional stdenv.isDarwin shortenPerlShebang;
 122   postInstall = lib.optionalString stdenv.isDarwin ''
 123     shortenPerlShebang $out/bin/exiftool
 124   '';
 125 };
 126 ```
 127
 128 This will remove the `-I` flags from the shebang line, rewrite them in the `use lib` form, and put them on the next line instead. This function can be given any number of Perl scripts as arguments; it will modify them in-place.
 129
 130 ### Generation from CPAN {#ssec-generation-from-CPAN}
 131
 132 Nix expressions for Perl packages can be generated (almost) automatically from CPAN. This is done by the program `nix-generate-from-cpan`, which can be installed as follows:
 133
 134 ```ShellSession
 135 $ nix-env -f "<nixpkgs>" -iA nix-generate-from-cpan
 136 ```
 137
 138 Substitute `<nixpkgs>` by the path of a nixpkgs clone to use the latest version.
 139
 140 This program takes a Perl module name, looks it up on CPAN, fetches and unpacks the corresponding package, and prints a Nix expression on standard output. For example:
 141
 142 ```ShellSession
 143 $ nix-generate-from-cpan XML::Simple
 144   XMLSimple = buildPerlPackage rec {
 145     pname = "XML-Simple";
 146     version = "2.22";
 147     src = fetchurl {
 148       url = "mirror://cpan/authors/id/G/GR/GRANTM/XML-Simple-2.22.tar.gz";
 149       hash = "sha256-uUUO8i6pZErl1q2ghtxDAPoQW+BQogMOvU79KMGY60k=";
 150     };
 151     propagatedBuildInputs = [ XMLNamespaceSupport XMLSAX XMLSAXExpat ];
 152     meta = {
 153       description = "An API for simple XML files";
 154       license = with lib.licenses; [ artistic1 gpl1Plus ];
 155     };
 156   };
 157 ```
 158
 159 The output can be pasted into `pkgs/top-level/perl-packages.nix` or wherever else you need it.
 160
 161 ### Cross-compiling modules {#ssec-perl-cross-compilation}
 162
 163 Nixpkgs has experimental support for cross-compiling Perl modules. In many cases, it will just work out of the box, even for modules with native extensions. Sometimes, however, the Makefile.PL for a module may (indirectly) import a native module. In that case, you will need to make a stub for that module that will satisfy the Makefile.PL and install it into `lib/perl5/site_perl/cross_perl/${perl.version}`. See the `postInstall` for `DBI` for an example.